[arch-commits] Commit in yder/repos (2 files)

[Antonio Rojas]

    Date: Saturday, June 18, 2022 @ 18:48:38
  Author: arojas
Revision: 1238531

archrelease: copy trunk to community-staging-x86_64

Added:
  yder/repos/community-staging-x86_64/
  yder/repos/community-staging-x86_64/PKGBUILD
    (from rev 1238530, yder/trunk/PKGBUILD)

----------+
 PKGBUILD |   48 ++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

Copied: yder/repos/community-staging-x86_64/PKGBUILD (from rev 1238530, yder/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-06-18 18:48:38 UTC (rev 1238531)
@@ -0,0 +1,48 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+
+pkgname=yder
+pkgver=1.4.17
+pkgrel=1
+pkgdesc='Logging library for C applications'
+arch=(x86_64)
+url=https://github.com/babelouest/yder
+license=(LGPL2.1)
+depends=(
+  glibc
+  liborcania.so
+  libsystemd.so
+)
+makedepends=(
+  cmake
+  doxygen
+  git
+  graphviz
+  ninja
+  systemd
+)
+provides=(libyder.so)
+_tag=28206b26635abcaab47e81984f891c9f74b5bcff
+source=(git+https://github.com/babelouest/yder.git#tag=${_tag})
+validpgpkeys=(8405B02FCC28EF9744C8F253FE82139440BD22B9) # Nicolas Mora <nicolas at babelouest.org>
+b2sums=(SKIP)
+
+pkgver() {
+  cd yder
+  git describe --tags | sed 's/^v//'
+}
+
+build() {
+  cmake -S yder -B build -G Ninja \
+    -DCMAKE_BUILD_TYPE=None \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DBUILD_YDER_DOCUMENTATION=ON
+  ninja -C build doc
+}
+
+package() {
+  DESTDIR="${pkgdir}" ninja -C build install
+  install -dm 755 "${pkgdir}"/usr/share/doc
+  cp -dr --no-preserve=ownership yder/doc/html "${pkgdir}"/usr/share/doc/yder/
+}
+
+# vim: ts=2 sw=2 et: