[arch-commits] Commit in ulfius/repos (2 files)

[Antonio Rojas]

    Date: Saturday, June 18, 2022 @ 18:52:01
  Author: arojas
Revision: 1238535

archrelease: copy trunk to community-staging-x86_64

Added:
  ulfius/repos/community-staging-x86_64/
  ulfius/repos/community-staging-x86_64/PKGBUILD
    (from rev 1238534, ulfius/trunk/PKGBUILD)

----------+
 PKGBUILD |   51 +++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)

Copied: ulfius/repos/community-staging-x86_64/PKGBUILD (from rev 1238534, ulfius/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-06-18 18:52:01 UTC (rev 1238535)
@@ -0,0 +1,51 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+
+pkgname=ulfius
+pkgver=2.7.10
+pkgrel=1
+pkgdesc='HTTP Framework for REST Applications in C'
+arch=(x86_64)
+url=https://github.com/babelouest/ulfius
+license=(LGPL2.1)
+depends=(
+  glibc
+  gnutls
+  jansson
+  libcurl.so
+  libmicrohttpd.so
+  liborcania.so
+  libyder.so
+  zlib
+)
+makedepends=(
+  cmake
+  doxygen
+  git
+  graphviz
+  ninja
+)
+provides=(libulfius.so)
+_tag=ee2ef2952b2e90b892eccba0fd4e109f62876cf6
+source=(git+https://github.com/babelouest/ulfius.git#tag=${_tag})
+validpgpkeys=(8405B02FCC28EF9744C8F253FE82139440BD22B9) # Nicolas Mora <nicolas at babelouest.org>
+b2sums=(SKIP)
+
+pkgver() {
+  cd ulfius
+  git describe --tags | sed 's/^v//'
+}
+
+build() {
+  cmake -S ulfius -B build -G Ninja \
+    -DCMAKE_BUILD_TYPE=None \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DBUILD_ULFIUS_DOCUMENTATION=ON
+  ninja -C build doc
+}
+
+package() {
+  DESTDIR="${pkgdir}" ninja -C build install
+  cp -dr --no-preserve=ownership ulfius/doc/html "${pkgdir}"/usr/share/doc/ulfius/
+}
+
+# vim: ts=2 sw=2 et: