[arch-commits] Commit in iddawc/repos (2 files)

[Antonio Rojas]

    Date: Saturday, June 18, 2022 @ 18:55:01
  Author: arojas
Revision: 1238539

archrelease: copy trunk to community-staging-x86_64

Added:
  iddawc/repos/community-staging-x86_64/
  iddawc/repos/community-staging-x86_64/PKGBUILD
    (from rev 1238538, iddawc/trunk/PKGBUILD)

----------+
 PKGBUILD |   51 +++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)

Copied: iddawc/repos/community-staging-x86_64/PKGBUILD (from rev 1238538, iddawc/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-06-18 18:55:01 UTC (rev 1238539)
@@ -0,0 +1,51 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+
+pkgname=iddawc
+pkgver=1.1.4
+pkgrel=1
+pkgdesc='OAuth2 and OIDC client library'
+arch=(x86_64)
+url=https://github.com/babelouest/iddawc
+license=(LGPL2.1)
+depends=(
+  glibc
+  liborcania.so
+  librhonabwy.so
+  libulfius.so
+  libyder.so
+)
+makedepends=(
+  cmake
+  doxygen
+  git
+  graphviz
+  ninja
+  systemd
+)
+provides=(libiddawc.so)
+_tag=a5f0851ddb1ce66a5816bc61ffbab4674cd3b524
+source=(git+https://github.com/babelouest/iddawc.git#tag=${_tag})
+validpgpkeys=(8405B02FCC28EF9744C8F253FE82139440BD22B9) # Nicolas Mora <nicolas at babelouest.org>
+b2sums=(SKIP)
+
+pkgver() {
+  cd iddawc
+  git describe --tags | sed 's/^v//'
+}
+
+build() {
+  export CFLAGS+=" -Wno-maybe-uninitialized"
+  cmake -S iddawc -B build -G Ninja \
+    -DCMAKE_BUILD_TYPE=None \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DBUILD_IDDAWC_DOCUMENTATION=ON
+  ninja -C build doc
+}
+
+package() {
+  DESTDIR="${pkgdir}" ninja -C build install
+  install -dm 755 "${pkgdir}"/usr/share/doc/iddawc
+  cp -dr --no-preserve=ownership iddawc/doc/html "${pkgdir}"/usr/share/doc/iddawc/
+}
+
+# vim: ts=2 sw=2 et: