[arch-commits] Commit in lib32-libproxy/repos (2 files)

[Jan Steffens]

    Date: Tuesday, June 21, 2022 @ 22:27:28
  Author: heftig
Revision: 1238879

archrelease: copy trunk to multilib-testing-x86_64

Added:
  lib32-libproxy/repos/multilib-testing-x86_64/
  lib32-libproxy/repos/multilib-testing-x86_64/PKGBUILD
    (from rev 1238878, lib32-libproxy/trunk/PKGBUILD)

----------+
 PKGBUILD |   69 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 69 insertions(+)

Copied: lib32-libproxy/repos/multilib-testing-x86_64/PKGBUILD (from rev 1238878, lib32-libproxy/trunk/PKGBUILD)
===================================================================
--- multilib-testing-x86_64/PKGBUILD	                        (rev 0)
+++ multilib-testing-x86_64/PKGBUILD	2022-06-21 22:27:28 UTC (rev 1238879)
@@ -0,0 +1,69 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: TryA <tryagainprod at gmail.com>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+# Contributor: josephgbr <rafael.f.f1 at gmail.com>
+
+pkgname=lib32-libproxy
+pkgver=0.4.18
+pkgrel=1
+pkgdesc="Automatic proxy configuration management library (32-bit)"
+url="https://libproxy.github.io/libproxy/"
+arch=(x86_64)
+license=(LGPL)
+depends=(
+  lib32-dbus
+  lib32-gcc-libs
+  lib32-glib2
+  lib32-zlib
+  libproxy
+)
+makedepends=(
+  cmake
+  git
+  ninja
+)
+options=(debug)
+_commit=caccaf28e3df6ea612d2d4b39f781c4324019fdb  # tags/0.4.18
+source=("git+https://github.com/libproxy/libproxy#commit=$_commit")
+b2sums=('SKIP')
+
+pkgver() {
+  cd libproxy
+  git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
+}
+
+prepare() {
+  cd libproxy
+
+  # Fix building without duktape
+  git cherry-pick -n c9b1f19c486b6ec590441b9c46965ab961d2677d
+}
+
+build() {
+  export CC='gcc -m32'
+  export CXX='g++ -m32'
+  export PKG_CONFIG=i686-pc-linux-gnu-pkg-config
+
+  cmake -S libproxy -B build -G Ninja \
+    -DBIPR=1 \
+    -DCMAKE_BUILD_TYPE=None \
+    -DCMAKE_CXX_FLAGS="$CXXFLAGS" \
+    -DCMAKE_C_FLAGS="$CFLAGS" \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_SKIP_RPATH=ON \
+    -DLIBEXEC_INSTALL_DIR=/usr/lib \
+    -DLIB_SUFFIX=32 \
+    -DWITH_{DUKTAPE,PERL,WEBKIT}=OFF
+  cmake --build build
+}
+
+check() {
+  cmake --build build --target test
+}
+
+package() {
+  DESTDIR="$pkgdir" cmake --install build
+  rm -r "$pkgdir"/usr/{bin,include,lib,share}
+}
+
+# vim:set sw=2 sts=-1 et: