[arch-commits] Commit in openmp/repos (3 files)
Evangelos Foutras
foutrelis at gemini.archlinux.org
Tue Jun 21 23:24:44 UTC 2022
Date: Tuesday, June 21, 2022 @ 23:24:44
Author: foutrelis
Revision: 449262
archrelease: copy trunk to staging-x86_64
Added:
openmp/repos/staging-x86_64/
openmp/repos/staging-x86_64/PKGBUILD
(from rev 449261, openmp/trunk/PKGBUILD)
openmp/repos/staging-x86_64/keys/
----------+
PKGBUILD | 47 +++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 47 insertions(+)
Copied: openmp/repos/staging-x86_64/PKGBUILD (from rev 449261, openmp/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD (rev 0)
+++ staging-x86_64/PKGBUILD 2022-06-21 23:24:44 UTC (rev 449262)
@@ -0,0 +1,47 @@
+# Maintainer: Evangelos Foutras <evangelos at foutrelis.com>
+
+pkgname=openmp
+pkgver=14.0.5
+pkgrel=1
+pkgdesc="LLVM OpenMP Runtime Library"
+arch=('x86_64')
+url="https://openmp.llvm.org/"
+license=('custom:Apache 2.0 with LLVM Exception')
+depends=('llvm-libs' 'libelf' 'libffi')
+makedepends=('llvm' 'clang' 'cmake' 'ninja')
+options=('!lto') # https://bugzilla.redhat.com/show_bug.cgi?id=1988155
+_source_base=https://github.com/llvm/llvm-project/releases/download/llvmorg-$pkgver
+source=($_source_base/openmp-$pkgver.src.tar.xz{,.sig})
+sha256sums=('1f74ede110ce1e2dc02fc163b04c4ce20dd49351407426e53292adbd4af6fdab'
+ 'SKIP')
+validpgpkeys+=('B6C8F98282B944E3B0D5C2530FC3042E345AD05D') # Hans Wennborg <hans at chromium.org>
+validpgpkeys+=('474E22316ABF4785A88C6E8EA2C794A986419D8A') # Tom Stellard <tstellar at redhat.com>
+
+prepare() {
+ cd openmp-$pkgver.src
+ mkdir build
+}
+
+build() {
+ cd openmp-$pkgver.src/build
+
+ local cmake_args=(
+ -G Ninja
+ -DCMAKE_BUILD_TYPE=Release
+ -DCMAKE_INSTALL_PREFIX=/usr
+ -DLIBOMP_INSTALL_ALIASES=OFF
+ )
+ cmake .. "${cmake_args[@]}"
+ ninja
+}
+
+package() {
+ cd openmp-$pkgver.src/build
+
+ DESTDIR="$pkgdir" ninja install
+ install -Dm644 ../LICENSE.TXT "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+
+ rm "$pkgdir/usr/lib/libarcher_static.a"
+}
+
+# vim:set ts=2 sw=2 et:
More information about the arch-commits
mailing list