[arch-commits] Commit in pyside2/repos (staging-x86_64 staging-x86_64/PKGBUILD)

[Antonio Rojas]

    Date: Wednesday, June 22, 2022 @ 07:55:36
  Author: arojas
Revision: 449298

archrelease: copy trunk to staging-x86_64

Added:
  pyside2/repos/staging-x86_64/
  pyside2/repos/staging-x86_64/PKGBUILD
    (from rev 449297, pyside2/trunk/PKGBUILD)

----------+
 PKGBUILD |  105 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 105 insertions(+)

Copied: pyside2/repos/staging-x86_64/PKGBUILD (from rev 449297, pyside2/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2022-06-22 07:55:36 UTC (rev 449298)
@@ -0,0 +1,105 @@
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=pyside2
+pkgname=(shiboken2 python-shiboken2 pyside2 pyside2-tools)
+_qtver=5.15.5
+_clangver=14.0.5
+pkgver=${_qtver/-/}
+pkgrel=2
+arch=(x86_64)
+url='https://www.qt.io'
+license=(LGPL)
+makedepends=(cmake python-setuptools llvm clang=$_clangver
+             qt5-multimedia qt5-tools qt5-sensors qt5-charts qt5-webengine qt5-datavis3d
+             qt5-websockets qt5-speech qt5-3d qt5-svg qt5-script qt5-scxml qt5-x11extras
+             qt5-quickcontrols2 qt5-serialport qt5-remoteobjects qt5-xmlpatterns)
+optdepends=('qt5-svg: QtSvg bindings'
+            'qt5-script: QtScript bindings'
+            'qt5-speech: QtTextToSpeech bindings'
+            'qt5-websockets: QtWebSockets bindings'
+            'qt5-webengine: QtWebEngine bindings'
+            'qt5-datavis3d: QtDataVisualization bindings'
+            'qt5-scxml: QtScxml bindings'
+            'qt5-sensors: QtSensors bindings'
+            'qt5-3d: Qt3D bindings'
+            'qt5-x11extras: QtX11Extras bindings'
+            'qt5-charts: QtCharts bindings'
+            'qt5-tools: QtHelp bindings'
+            'qt5-remoteobjects: QtRemoteObjects bindings'
+            'qt5-serialport: QtSerialPort bindings'
+            'qt5-quickcontrols2: QtQuickControls2 bindings')
+_pkgfqn=pyside-setup-opensource-src-$_qtver
+source=(https://download.qt.io/official_releases/QtForPython/pyside2/PySide2-$pkgver-src/${_pkgfqn}.tar.xz)
+sha256sums=('3920a4fb353300260c9bc46ff70f1fb975c5e7efa22e9d51222588928ce19b33')
+
+build() {
+  cmake -B build -S $_pkgfqn \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_BUILD_TYPE=None \
+    -DBUILD_TESTS=OFF \
+    -DPYTHON_EXECUTABLE=/usr/bin/python
+  cmake --build build
+}
+
+package_shiboken2() {
+  pkgdesc='Generates bindings for C++ libraries using CPython source code'
+  depends=(clang=$_clangver llvm libxslt qt5-xmlpatterns)
+
+  DESTDIR="$pkgdir" cmake --install build/sources/shiboken2
+# Provided in python-shiboken2
+  rm -r "$pkgdir"/usr/lib/{python*,libshiboken*}
+# Conflicts with shiboken6 and doesn't work anyway
+  rm "$pkgdir"/usr/bin/shiboken_tool.py
+}
+
+package_python-shiboken2() {
+  pkgdesc='Python bindings for shiboken2'
+  depends=(python)
+
+  DESTDIR="$pkgdir" cmake --install build/sources/shiboken2
+# Provided in shiboken2
+  rm -r "$pkgdir"/usr/{bin,include,lib/{cmake,pkgconfig}}
+
+# Install egg-info
+  cd $_pkgfqn
+  python setup.py egg_info --build-type=shiboken2
+  _pythonpath=`python -c "from sysconfig import get_path; print(get_path('platlib'))"`
+  cp -r shiboken2.egg-info "$pkgdir"/$_pythonpath
+}
+
+package_pyside2() {
+  pkgdesc='Enables the use of Qt5 APIs in Python applications'
+  depends=(python-shiboken2 qt5-declarative)
+  optdepends=('qt5-svg: QtSvg bindings'
+              'qt5-script: QtScript bindings'
+              'qt5-speech: QtTextToSpeech bindings'
+              'qt5-websockets: QtWebSockets bindings'
+              'qt5-webengine: QtWebEngine bindings'
+              'qt5-datavis3d: QtDataVisualization bindings'
+              'qt5-scxml: QtScxml bindings'
+              'qt5-sensors: QtSensors bindings'
+              'qt5-3d: Qt3D bindings'
+              'qt5-x11extras: QtX11Extras bindings'
+              'qt5-charts: QtCharts bindings'
+              'qt5-tools: QtHelp bindings'
+              'qt5-remoteobjects: QtRemoteObjects bindings'
+              'qt5-serialport: QtSerialPort bindings'
+              'qt5-quickcontrols2: QtQuickControls2 bindings')
+  provides=(qt5-python-bindings)
+
+  DESTDIR="$pkgdir" cmake --install build/sources/pyside2
+# Install egg-info
+  cd $_pkgfqn
+  python setup.py egg_info --build-type=pyside2
+  _pythonpath=`python -c "from sysconfig import get_path; print(get_path('platlib'))"`
+  cp -r PySide2.egg-info "$pkgdir"/$_pythonpath
+}
+
+package_pyside2-tools() {
+  pkgdesc='Tools for PySide2'
+  depends=(pyside2)
+
+  DESTDIR="$pkgdir" cmake --install build/sources/pyside2-tools
+  rm "$pkgdir"/usr/bin/{rcc,uic,designer} # provided by qt5-base
+}