[arch-commits] Commit in faust/repos (2 files)

[Evangelos Foutras]

    Date: Thursday, June 23, 2022 @ 01:59:35
  Author: foutrelis
Revision: 1239206

archrelease: copy trunk to community-staging-x86_64

Added:
  faust/repos/community-staging-x86_64/
  faust/repos/community-staging-x86_64/PKGBUILD
    (from rev 1239205, faust/trunk/PKGBUILD)

----------+
 PKGBUILD |  110 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 110 insertions(+)

Copied: faust/repos/community-staging-x86_64/PKGBUILD (from rev 1239205, faust/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-06-23 01:59:35 UTC (rev 1239206)
@@ -0,0 +1,110 @@
+# Maintainer: David Runge <dvzrv at archlinux.org>
+# Contributor: Albert Graef <aggraef at gmail.com>
+# Contributor: Bernardo Barros <bernardobarros at gmail dot com>
+# Contributor: bjoern lindig (bjoern _dot_ lindig _at_ google.com)
+
+pkgname=faust
+pkgver=2.40.0
+pkgrel=2
+pkgdesc="A functional programming language for realtime audio signal processing."
+arch=(x86_64)
+url="https://faust.grame.fr/"
+license=(GPL2)
+groups=(pro-audio)
+depends=(gcc-libs glibc llvm-libs libmicrohttpd)
+makedepends=(cmake libsndfile llvm xxd)
+optdepends=(
+  'clang: for sound2reader'
+  'csound: for faust2csound'
+  'gradle: for faust2android'
+  'graphviz: for faust2sig{,viewer}'
+  'gtk2: for faust2{jack,rosgtk}'
+  'inkscape: for faust2{pdf,png}'
+  'jack: for faust2{api,jack{,console,internal,server,rust},jaqt,netjackqt,nodejs,ros,rosgtk,rpinetjackconsole}'
+  'swig: for faust2android'
+  'libsndfile: for faust2{dummy,sndfile}'
+  'octave: for faust2octave'
+  'pd: for faust2puredata'
+  'portaudio: for faust2paqt'
+  'python: for faust2atomsnippets, faust2md and faust2sc.py'
+  'qt5-tools: for faust2{faustvst,jaqt,lv2}'
+  'rtaudio: for faust2raqt'
+  'ruby-rexml: for faust2sc and scbuilder'
+  'rust: for faust2jackrust'
+  'supercollider: for faust2supercollider'
+  'texlive-core: for faust2pdf'
+)
+provides=(libfaustmachine.so libfaust.so libOSCFaust.so libHTTPDFaust.so)
+options=(debug staticlibs)
+source=(https://github.com/grame-cncm/$pkgname/releases/download/$pkgver/$pkgname-$pkgver.tar.gz         $pkgname-llvm14.patch::https://github.com/grame-cncm/faust/commit/1275ec6774e0.patch)
+sha512sums=('7ecb334b95042caa3a44ecbb711a972b6f979afca4c67fc4f32acf548ed85472e941c6590a139464aeb5266c3e88fe639e2060a110a98e88fd7b1994e0a87650'
+            '15958650d4e60c000e646a25b7fae2da7331b03baae793d9890413e1ee9771c4f8f40cf9a398e3118240720f48765cfd416355771d5777632f723e286e55e447')
+b2sums=('31a4403d1d53379bd1824ab2b908c3236bb8cefd9ab599d71b72d214f328dcbd04fa144fbd7f8f5d8814c3d13926c8d043b351700baa6b7e048014bd3ca5a932'
+        '7d64bca3934ace798a2be1d217ac13f0df1a8ac76a07cd7a426f748e525eb41d5c1f51e5e2ee0cd8f3473816e4fdd086b822f3cc1daeebf8d10d447f86aa6088')
+
+prepare() {
+  cd $pkgname-$pkgver
+  patch -Np1 -i ../$pkgname-llvm14.patch
+}
+
+build() {
+  # prevent static libs from being mangled with LTO
+  CXXFLAGS+=' -ffat-lto-objects'
+
+  cd $pkgname-$pkgver
+  cmake -C build/backends/all.cmake \
+        -C build/targets/all.cmake \
+        -DCMAKE_INSTALL_PREFIX=/usr \
+        -DCMAKE_BUILD_TYPE=None \
+        -DINCLUDE_DYNAMIC=ON \
+        -DINCLUDE_STATIC=ON \
+        -DINCLUDE_ITP=ON \
+        -W no-dev \
+        -B $pkgname-build \
+        -S build
+  make VERBOSE=1 -C $pkgname-build
+  make VERBOSE=1 -C tools/sound2faust
+}
+
+package() {
+  depends+=(libsndfile.so)
+
+  cd $pkgname-$pkgver
+  make VERBOSE=1 PREFIX=/usr DESTDIR="$pkgdir" install -C $pkgname-build
+  make VERBOSE=1 PREFIX=/usr DESTDIR="$pkgdir" install -C tools/sound2faust
+
+  # docs
+  install -vDm 644 documentation/{,misc/}*.pdf -t "$pkgdir/usr/share/doc/$pkgname"
+
+  # examples
+  install -vd "$pkgdir/usr/share/$pkgname/examples"
+  cp -vR "examples/"* "$pkgdir/usr/share/$pkgname/examples/"
+
+  cd syntax-highlighting
+  # atom
+  install -vDm 644 atom/language-$pkgname/package.json -t "$pkgdir/usr/lib/atom/dot-atom/packages/language-$pkgname/"
+  install -vDm 644 atom/language-$pkgname/grammars/$pkgname.cson -t "$pkgdir/usr/lib/atom/dot-atom/packages/language-$pkgname/grammars/"
+  install -vDm 644 atom/language-$pkgname/settings/language-$pkgname.cson -t "$pkgdir/usr/lib/atom/dot-atom/packages/language-$pkgname/settings/"
+  install -vDm 644 atom/language-$pkgname/snippets/* -t "$pkgdir/usr/lib/atom/dot-atom/packages/language-$pkgname/snippets/"
+  install -vDm 644 atom/language-$pkgname/process-palette.json.linux "$pkgdir/usr/share/doc/$pkgname/process-palette.json"
+  # kate
+  install -vDm 644 $pkgname.xml -t "$pkgdir/usr/share/apps/katepart/syntax/"
+  # gedit
+  install -vDm 644 $pkgname.lang -t "$pkgdir/usr/share/gtksourceview-2.0/language-specs/"
+  install -vDm 644 $pkgname.lang -t "$pkgdir/usr/share/gtksourceview-3.0/language-specs/"
+  # highlight
+  install -vDm 644 dsp.lang -t "$pkgdir/usr/share/highlight/langDefs/"
+  # nano
+  install -vDm 644 $pkgname.nanorc -t "$pkgdir/usr/share/nano/"
+  # vim
+  install -vDm 644 $pkgname.vim -t "$pkgdir/usr/share/vim/vimfiles/syntax/"
+  # emacs
+  install -vDm 644 $pkgname-mode.el -t "$pkgdir/usr/share/emacs/site-lisp/"
+
+  # remove unusable scripts
+  rm -v "$pkgdir/usr/bin/faust2au"
+  # remove precompiled shared libraries for android:
+  # https://github.com/grame-cncm/faust/issues/370
+  rm -rvf "$pkgdir/usr/share/faust/android/app/"{lib,oboe} "$pkgdir/usr/share/faust/smartKeyboard/android/app/oboe"
+}
+