[arch-commits] Commit in (qbe qbe/repos qbe/trunk qbe/trunk/PKGBUILD)

[George Rawlinson]

    Date: Thursday, June 23, 2022 @ 22:38:37
  Author: grawlinson
Revision: 1239295

addpkg: qbe 1.0-1

Added:
  qbe/
  qbe/repos/
  qbe/trunk/
  qbe/trunk/PKGBUILD

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Added: qbe/trunk/PKGBUILD
===================================================================
--- qbe/trunk/PKGBUILD	                        (rev 0)
+++ qbe/trunk/PKGBUILD	2022-06-23 22:38:37 UTC (rev 1239295)
@@ -0,0 +1,44 @@
+# Maintainer: George Rawlinson <grawlinson at archlinux.org>
+
+pkgname=qbe
+pkgver=1.0
+pkgrel=1
+pkgdesc='Small embeddable C compiler backend'
+arch=('x86_64')
+url='https://c9x.me/compile/'
+license=('MIT')
+depends=('glibc')
+makedepends=('git')
+_commit='cd778b44ba11925d65ee10ff29fe22d4a45809dd'
+source=("git://c9x.me/qbe.git#commit=$_commit")
+b2sums=('SKIP')
+
+pkgver() {
+  cd qbe
+
+  git describe --tags | sed 's/^v//'
+}
+
+build() {
+  cd qbe
+
+  make
+}
+
+check() {
+  cd qbe
+
+  make -k check
+}
+
+package() {
+  cd qbe
+
+  make DESTDIR="$pkgdir" PREFIX=/usr install
+
+  # documentation
+  install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" doc/*
+
+  # license
+  install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
+}