[arch-commits] Commit in python-resolvelib/trunk (PKGBUILD)

[David Runge]

    Date: Monday, June 27, 2022 @ 14:40:29
  Author: dvzrv
Revision: 449484

upgpkg: python-resolvelib 0.8.1-1: Upgrade to 0.8.1.

Add upstream ticket for missing tests in sdist tarballs on pypi.org.
Abstract name with variable.
Remove unnecessary quotes and curly braces.
Run pytest directly in check() after installing to temporary location.
Switch to PEP517.

Modified:
  python-resolvelib/trunk/PKGBUILD

----------+
 PKGBUILD |   42 ++++++++++++++++++++++++++----------------
 1 file changed, 26 insertions(+), 16 deletions(-)

Modified: PKGBUILD
===================================================================
--- PKGBUILD	2022-06-27 11:01:32 UTC (rev 449483)
+++ PKGBUILD	2022-06-27 14:40:29 UTC (rev 449484)
@@ -1,31 +1,41 @@
+# Maintainer: David Runge <dvzrv at archlinux.org>
 # Maintainer: Felix Yan <felixonmars at archlinux.org>
 
+_name=resolvelib
 pkgname=python-resolvelib
-pkgver=0.5.5
-pkgrel=4
+pkgver=0.8.1
+pkgrel=1
 pkgdesc="Resolve abstract dependencies into concrete ones"
 url="https://github.com/sarugaku/resolvelib"
-license=('ISC')
-arch=('any')
-depends=('python')
-makedepends=('python-setuptools')
-checkdepends=('python-commentjson' 'python-pytest-runner')
-source=("$pkgbase-$pkgver.tar.gz::https://github.com/sarugaku/resolvelib/archive/$pkgver.tar.gz")
-sha512sums=('3da39201c4472d45466750119282fc34591b6d79eb4e6e71ca3f221e43dceead213058b4b72bee00083e9885650a47486bd7496264fba10f623aec7c19dabf00')
+license=(custom:ISC)
+arch=(any)
+depends=(python)
+makedepends=(python-build python-installer python-setuptools python-wheel)
+checkdepends=(python-commentjson python-packaging python-pytest)
+# test files not in pypi sdist tarballs: https://github.com/sarugaku/resolvelib/issues/108
+# source=(https://files.pythonhosted.org/packages/source/${_name::1}/$_name/$_name-$pkgver.tar.gz)
+source=($_name-$pkgver.tar.gz::https://github.com/sarugaku/resolvelib/archive/refs/tags/$pkgver.tar.gz)
+sha512sums=('bc99d0661f3605d97074066df3c57edec8db40f66111f0d7a23ad88097ba4a162368ab396ef75632d09cd8a76417fbee2554d0cdb2f797795c246d16e7e3b955')
+b2sums=('59bb02a08cf0f9bc6070cd5c5109826a7cacc5bda07479358fd591ff018bad761b53ed48f0a330e5ef60b8fa8d5db14ef044b662423e372aad7fc477df5b97ef')
 
 build() {
-  cd resolvelib-$pkgver
-  python setup.py build
+  cd $_name-$pkgver
+  python -m build --wheel --no-isolation
 }
 
 check() {
-  cd resolvelib-$pkgver
-  python setup.py pytest
+  local _site_packages=$(python -c "import site; print(site.getsitepackages()[0])")
+
+  cd $_name-$pkgver
+  # install to temporary location
+  python -m installer --destdir=test_dir dist/*.whl
+  export PYTHONPATH="test_dir/$_site_packages:$PYTHONPATH"
+  pytest -vv
 }
 
 package() {
-  cd resolvelib-$pkgver
-  python setup.py install --root="$pkgdir" --optimize=1
+  cd $_name-$pkgver
+  python -m installer --destdir="$pkgdir" dist/*.whl
 
-  install -Dm644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
+  install -vDm 644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
 }