[arch-commits] Commit in openal/repos/extra-x86_64 (PKGBUILD PKGBUILD)

[Jan Steffens]

    Date: Monday, June 27, 2022 @ 17:13:09
  Author: heftig
Revision: 449492

archrelease: copy trunk to extra-x86_64

Added:
  openal/repos/extra-x86_64/PKGBUILD
    (from rev 449491, openal/trunk/PKGBUILD)
Deleted:
  openal/repos/extra-x86_64/PKGBUILD

----------+
 PKGBUILD |  137 +++++++++++++++++++++++++++++--------------------------------
 1 file changed, 67 insertions(+), 70 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2022-06-27 17:05:55 UTC (rev 449491)
+++ PKGBUILD	2022-06-27 17:13:09 UTC (rev 449492)
@@ -1,70 +0,0 @@
-# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
-# Contributor: Allan McRae <allan at archlinux.org>
-# Contributor: Jason Chu <jchu at xentac.net>
-
-pkgbase=openal
-pkgname=(openal openal-examples)
-pkgver=1.22.0
-pkgrel=1
-pkgdesc="Cross-platform 3D audio library, software implementation"
-arch=(x86_64)
-url="https://github.com/kcat/openal-soft"
-license=(LGPL)
-depends=(gcc-libs)
-makedepends=(alsa-lib libpulse fluidsynth portaudio jack pipewire qt5-base sdl2
-             libsndfile ffmpeg libmysofa git cmake ninja)
-optdepends=('qt5-base: alsoft-config GUI Configurator'
-            'fluidsynth: MIDI rendering'
-            'libmysofa: makemhr tool')
-options=(debug)
-_commit=c1c63a27de66cd44ef756b190a73bfa8bc6dbbab  # master
-source=("git+https://github.com/kcat/openal-soft#commit=$_commit")
-b2sums=('SKIP')
-
-pkgver() {
-  cd openal-soft
-  git describe --tags | sed 's/^openal-soft-//;s/-/+/g'
-}
-
-prepare() {
-  cd openal-soft
-
-  # Fixup missing tag
-  git tag -f 1.22.0 c1c63a27de66cd44ef756b190a73bfa8bc6dbbab
-}
-
-build() {
-  cmake -S openal-soft -B build -G Ninja \
-    -DCMAKE_INSTALL_PREFIX=/usr \
-    -DCMAKE_BUILD_TYPE=None \
-    -DCMAKE_INSTALL_LIBDIR=lib
-  cmake --build build
-}
-
-_pick() {
-  local p="$1" f d; shift
-  for f; do
-    d="$srcdir/$p/${f#$pkgdir/}"
-    mkdir -p "$(dirname "$d")"
-    mv "$f" "$d"
-    rmdir -p --ignore-fail-on-non-empty "$(dirname "$f")"
-  done
-}
-
-package_openal() {
-  provides+=(libopenal.so)
-
-  DESTDIR="$pkgdir" cmake --install build
-  install -Dt "$pkgdir/usr/share/doc/openal" -m644 openal-soft/docs/*
-
-  cd "$pkgdir"
-  _pick examples usr/bin/al{ffplay,hrtf,latency,loopback,multireverb}
-  _pick examples usr/bin/al{play,record,reverb,stream,tonegen}
-}
-
-package_openal-examples() {
-  pkgdesc+=" (example programs)"
-  depends=("openal=$pkgver-$pkgrel" sdl2 libsndfile ffmpeg)
-  optdepends=()
-  mv examples/* "$pkgdir"
-}

Copied: openal/repos/extra-x86_64/PKGBUILD (from rev 449491, openal/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2022-06-27 17:13:09 UTC (rev 449492)
@@ -0,0 +1,67 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Allan McRae <allan at archlinux.org>
+# Contributor: Jason Chu <jchu at xentac.net>
+
+pkgbase=openal
+pkgname=(openal openal-examples)
+pkgver=1.22.2
+pkgrel=1
+pkgdesc="Cross-platform 3D audio library, software implementation"
+arch=(x86_64)
+url="https://github.com/kcat/openal-soft"
+license=(LGPL)
+depends=(gcc-libs)
+makedepends=(alsa-lib libpulse fluidsynth portaudio jack pipewire qt5-base sdl2
+             libsndfile ffmpeg libmysofa git cmake ninja)
+optdepends=('qt5-base: alsoft-config GUI Configurator'
+            'fluidsynth: MIDI rendering'
+            'libmysofa: makemhr tool')
+options=(debug)
+_commit=dc83d99c95a42c960150ddeee06c124134b52208  # tags/1.22.2
+source=("git+https://github.com/kcat/openal-soft#commit=$_commit")
+b2sums=('SKIP')
+
+pkgver() {
+  cd openal-soft
+  git describe --tags | sed 's/^openal-soft-//;s/[^-]*-g/r&/;s/-/+/g'
+}
+
+prepare() {
+  cd openal-soft
+}
+
+build() {
+  cmake -S openal-soft -B build -G Ninja \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_BUILD_TYPE=None \
+    -DCMAKE_INSTALL_LIBDIR=lib
+  cmake --build build
+}
+
+_pick() {
+  local p="$1" f d; shift
+  for f; do
+    d="$srcdir/$p/${f#$pkgdir/}"
+    mkdir -p "$(dirname "$d")"
+    mv "$f" "$d"
+    rmdir -p --ignore-fail-on-non-empty "$(dirname "$f")"
+  done
+}
+
+package_openal() {
+  provides+=(libopenal.so)
+
+  DESTDIR="$pkgdir" cmake --install build
+  install -Dt "$pkgdir/usr/share/doc/openal" -m644 openal-soft/docs/*
+
+  cd "$pkgdir"
+  _pick examples usr/bin/al{ffplay,hrtf,latency,loopback,multireverb}
+  _pick examples usr/bin/al{play,record,reverb,stream,tonegen}
+}
+
+package_openal-examples() {
+  pkgdesc+=" (example programs)"
+  depends=("openal=$pkgver-$pkgrel" sdl2 libsndfile ffmpeg)
+  optdepends=()
+  mv examples/* "$pkgdir"
+}