[arch-commits] Commit in harfbuzz/repos (testing-x86_64 testing-x86_64/PKGBUILD)

[Jan Steffens]

    Date: Monday, June 27, 2022 @ 21:24:48
  Author: heftig
Revision: 449510

archrelease: copy trunk to testing-x86_64

Added:
  harfbuzz/repos/testing-x86_64/
  harfbuzz/repos/testing-x86_64/PKGBUILD
    (from rev 449509, harfbuzz/trunk/PKGBUILD)

----------+
 PKGBUILD |   85 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 85 insertions(+)

Copied: harfbuzz/repos/testing-x86_64/PKGBUILD (from rev 449509, harfbuzz/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2022-06-27 21:24:48 UTC (rev 449510)
@@ -0,0 +1,85 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+
+pkgbase=harfbuzz
+pkgname=(harfbuzz harfbuzz-icu)
+pkgver=4.4.0
+pkgrel=1
+pkgdesc="OpenType text shaping engine"
+url="https://www.freedesktop.org/wiki/Software/HarfBuzz"
+arch=(x86_64)
+license=(MIT)
+makedepends=(glib2 freetype2 graphite cairo icu gobject-introspection gtk-doc
+             ragel git python meson chafa)
+checkdepends=(python-fonttools python-setuptools)
+options=(debug)
+_commit=8537d681728e141550b4470b591fa059f6ca2670  # tags/4.4.0^0
+source=("git+https://github.com/harfbuzz/harfbuzz#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd harfbuzz
+  git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
+}
+
+prepare() {
+  cd harfbuzz
+
+  # https://github.com/harfbuzz/harfbuzz/issues/3684
+  git cherry-pick -n 69d53f3e7fde 5da341ce9235
+}
+
+build() {
+  # Harfbuzz wants no exceptions
+  CFLAGS="${CFLAGS/-fexceptions/}"
+  CXXFLAGS="${CXXFLAGS/-fexceptions/}"
+
+  arch-meson harfbuzz build \
+    -D graphite2=enabled
+  meson compile -C build
+}
+
+check() {
+  mkdir -p tmp
+  TMPDIR="$PWD/tmp" meson test -C build --print-errorlogs
+  rm -r tmp
+}
+
+_pick() {
+  local p="$1" f d; shift
+  for f; do
+    d="$srcdir/$p/${f#$pkgdir/}"
+    mkdir -p "$(dirname "$d")"
+    mv "$f" "$d"
+    rmdir -p --ignore-fail-on-non-empty "$(dirname "$f")"
+  done
+}
+
+package_harfbuzz() {
+  depends=(glib2 freetype2 graphite libglib-2.0.so libfreetype.so
+           libgobject-2.0.so)
+  provides=(libharfbuzz.so libharfbuzz-subset.so libharfbuzz-gobject.so)
+  optdepends=('cairo: hb-view program'
+              'chafa: hb-view program')
+
+  meson install -C build --destdir "$pkgdir"
+
+  ( cd "$pkgdir"
+
+    _pick hb-icu usr/lib/libharfbuzz-icu*
+    _pick hb-icu usr/lib/pkgconfig/harfbuzz-icu.pc
+    _pick hb-icu usr/include/harfbuzz/hb-icu.h
+  )
+
+  install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 harfbuzz/COPYING
+}
+
+package_harfbuzz-icu() {
+  pkgdesc+=" - ICU integration"
+  depends=("harfbuzz=$pkgver-$pkgrel" libicuuc.so libharfbuzz.so)
+  provides=(libharfbuzz-icu.so)
+
+  mv hb-icu/* "$pkgdir"
+
+  install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 harfbuzz/COPYING
+}