[arch-commits] Commit in inkscape/repos (3 files)

[Felix Yan]

    Date: Wednesday, March 2, 2022 @ 10:19:40
  Author: felixonmars
Revision: 438283

archrelease: copy trunk to staging-x86_64

Added:
  inkscape/repos/staging-x86_64/
  inkscape/repos/staging-x86_64/PKGBUILD
    (from rev 438282, inkscape/trunk/PKGBUILD)
  inkscape/repos/staging-x86_64/poppler-22.03.0.patch
    (from rev 438282, inkscape/trunk/poppler-22.03.0.patch)

-----------------------+
 PKGBUILD              |   81 ++++++++++++++++++++++++++++++++++++++++++++++++
 poppler-22.03.0.patch |   17 ++++++++++
 2 files changed, 98 insertions(+)

Copied: inkscape/repos/staging-x86_64/PKGBUILD (from rev 438282, inkscape/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2022-03-02 10:19:40 UTC (rev 438283)
@@ -0,0 +1,81 @@
+# Maintainer: Gaetan Bisson <bisson at archlinux.org>
+# Contributor: Tobias Kieslich <tobias at justdreams.de>
+# Contributor: tobias <tobias at archlinux.org>
+
+pkgname=inkscape
+pkgver=1.1.2
+_tag='0a00cf5339ab09436cbe123d22e98fb791619733' # git rev-parse INKSCAPE_${pkgver/./_}
+pkgrel=2
+pkgdesc='Professional vector graphics editor'
+url='https://inkscape.org/'
+license=('GPL' 'LGPL')
+arch=('x86_64')
+makedepends=('cmake' 'boost' 'git')
+
+depends=(
+	'dbus-glib'
+	'double-conversion'
+	'gc'
+	'graphicsmagick'
+	'gsl'
+	'gspell'
+	'gtkmm3'
+	'lcms2'
+	'lib2geom'
+	'libcdr'
+	'libjpeg-turbo'
+	'libvisio'
+	'libxslt'
+	'poppler-glib'
+	'potrace'
+	'python'
+	'ttf-font'
+)
+
+optdepends=(
+	'fig2dev: xfig input'
+	'gvfs: import clip art'
+	'pstoedit: latex formulas'
+	'python-lxml: some extensions'
+	'python-numpy: some extensions'
+	'scour: optimized SVG output, some extensions'
+	'texlive-core: latex formulas'
+)
+
+#source=("https://media.inkscape.org/dl/resources/file/${pkgname}-${pkgver}.tar.bz2")
+source=("git+https://gitlab.com/inkscape/inkscape.git#tag=${_tag}"
+        poppler-22.03.0.patch)
+sha256sums=('SKIP'
+            'cc4910d8db7ae40f280e144fd575fe921e781771e02776570371709e3d3ed42a')
+
+_backports=(
+)
+
+prepare() {
+	cd "${pkgname}"
+	git submodule init
+	git submodule update
+
+	local _c
+	for _c in "${_backports[@]}"; do
+		git log --oneline -1 "${_c}"
+		git cherry-pick -n "${_c}"
+	done
+
+	patch -Np1 -i ../poppler-22.03.0.patch
+}
+
+build() {
+	mkdir -p build
+	export PKG_CONFIG_PATH='/usr/lib/imagemagick6/pkgconfig'
+	cmake -H${pkgname} -Bbuild \
+		-DCMAKE_BUILD_TYPE=Release \
+		-DCMAKE_INSTALL_PREFIX:PATH=/usr \
+		-DWITH_DBUS=ON \
+
+	cmake --build build
+}
+
+package() {
+	DESTDIR="${pkgdir}" cmake --build build --target install
+}

Copied: inkscape/repos/staging-x86_64/poppler-22.03.0.patch (from rev 438282, inkscape/trunk/poppler-22.03.0.patch)
===================================================================
--- staging-x86_64/poppler-22.03.0.patch	                        (rev 0)
+++ staging-x86_64/poppler-22.03.0.patch	2022-03-02 10:19:40 UTC (rev 438283)
@@ -0,0 +1,17 @@
+diff --git a/src/extension/internal/pdfinput/pdf-input.cpp b/src/extension/internal/pdfinput/pdf-input.cpp
+index e6204f650c..b2424e996e 100644
+--- a/src/extension/internal/pdfinput/pdf-input.cpp
++++ b/src/extension/internal/pdfinput/pdf-input.cpp
+@@ -668,8 +668,12 @@ PdfInput::open(::Inkscape::Extension::Input * /*mod*/, const gchar * uri) {
+ 
+     // poppler does not use glib g_open. So on win32 we must use unicode call. code was copied from
+     // glib gstdio.c
++#if POPPLER_CHECK_VERSION(22, 3, 0)
++    pdf_doc = std::make_shared<PDFDoc>(std::make_unique<GooString>(uri));   // TODO: Could ask for password
++#else
+     GooString *filename_goo = new GooString(uri);
+     pdf_doc = std::make_shared<PDFDoc>(filename_goo, nullptr, nullptr, nullptr);   // TODO: Could ask for password
++#endif
+ 
+     if (!pdf_doc->isOk()) {
+         int error = pdf_doc->getErrorCode();