[arch-commits] Commit in stone-soup/repos/community-x86_64 (3 files)
Ivy Foster
escondida at gemini.archlinux.org
Thu Mar 3 01:45:08 UTC 2022
Date: Thursday, March 3, 2022 @ 01:45:08
Author: escondida
Revision: 1140167
archrelease: copy trunk to community-x86_64
Added:
stone-soup/repos/community-x86_64/PKGBUILD
(from rev 1140165, stone-soup/trunk/PKGBUILD)
Deleted:
stone-soup/repos/community-x86_64/PKGBUILD
stone-soup/repos/community-x86_64/stone-soup.install
--------------------+
PKGBUILD | 136 ++++++++++++++++++++++++++++-----------------------
stone-soup.install | 11 ----
2 files changed, 75 insertions(+), 72 deletions(-)
Deleted: PKGBUILD
===================================================================
--- PKGBUILD 2022-03-03 01:45:07 UTC (rev 1140166)
+++ PKGBUILD 2022-03-03 01:45:08 UTC (rev 1140167)
@@ -1,61 +0,0 @@
-# Maintainer: Jakob Gruber <jakob.gruber at gmail.com>
-
-pkgname=stone-soup
-pkgver=0.27.1
-pkgrel=3
-pkgdesc='Open-source, single-player, role-playing roguelike game of exploration and treasure-hunting'
-arch=('x86_64')
-url='https://crawl.develz.org/'
-depends=('lua51' 'ncurses' 'sdl2_image' 'sqlite' 'glu' 'freetype2' 'ttf-dejavu' 'python-yaml')
-makedepends=('bison' 'flex' 'gendesk' 'mesa' 'pngcrush')
-conflicts=('crawl' 'stone-soup-tile' 'stone-soup-git')
-license=(custom GPL2)
-install=stone-soup.install
-source=("stone-soup-$pkgver.tar.xz::https://github.com/crawl/crawl/releases/download/$pkgver/stone_soup-$pkgver-nodeps.tar.xz")
-md5sums=('ce8e390097fbfb3f56e8f6744ab64736')
-
-package() {
- gendesk -n --pkgname "$pkgname" --pkgdesc "$pkgdesc" \
- --exec 'crawl-tiles' --name 'Dungeon Crawl Stone Soup' PKGBUILD
-
- cd "stone_soup-${pkgver}/source"
-
- sed -i 's/INSTALL_UGRP := games:games/INSTALL_UGRP := root:root/' Makefile
-
- # first build and install tiles version
-
- make DESTDIR="${pkgdir}" \
- SAVEDIR="~/.crawl/" \
- DATADIR="/usr/share/${pkgname}/data" \
- TILES=y \
- EXTERNAL_LDFLAGS=$LDFLAGS \
- prefix=/usr \
- bin_prefix=bin \
- install
-
- # rename tiles executable to avoid clashing with console crawl
-
- mv "${pkgdir}/usr/bin/crawl" "${pkgdir}/usr/bin/crawl-tiles"
-
- # then build and install console version
-
- make DESTDIR="${pkgdir}" \
- SAVEDIR="~/.crawl/" \
- DATADIR="/usr/share/${pkgname}/data" \
- EXTERNAL_LDFLAGS=$LDFLAGS \
- prefix=/usr \
- bin_prefix=bin \
- install
-
- # install crawl license
-
- install -D -m644 ../LICENSE \
- "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
-
- # install icon and .desktop file
-
- install -D -m644 dat/tiles/stone_soup_icon-32x32.png \
- "${pkgdir}/usr/share/pixmaps/${pkgname}.png"
- install -D -m644 "${srcdir}/${pkgname}.desktop" \
- "${pkgdir}/usr/share/applications/${pkgname}.desktop"
-}
Copied: stone-soup/repos/community-x86_64/PKGBUILD (from rev 1140165, stone-soup/trunk/PKGBUILD)
===================================================================
--- PKGBUILD (rev 0)
+++ PKGBUILD 2022-03-03 01:45:08 UTC (rev 1140167)
@@ -0,0 +1,75 @@
+# Maintainer: Ivy Foster <iff at archlinux.org>
+# Contributor: Jakob Gruber <jakob.gruber at gmail.com>
+
+pkgname=stone-soup
+pkgdesc='Open-source, single-player, role-playing roguelike game of exploration and treasure-hunting'
+url='https://crawl.develz.org/'
+license=(custom GPL2)
+
+pkgver=0.28.0
+pkgrel=1
+arch=(x86_64)
+
+# line-by-line: both versions, graphical, ncurses
+depends=(
+ lua51 python-yaml sqlite \
+ freetype2 glu libpng sdl2_image ttf-dejavu \
+ ncurses
+)
+makedepends=(bison flex gendesk mesa pngcrush)
+conflicts=(crawl stone-soup-tile stone-soup-git)
+
+source=("stone-soup-$pkgver.tar.xz::https://github.com/crawl/crawl/releases/download/$pkgver/stone_soup-$pkgver-nodeps.tar.xz")
+# checksums provided by packager; take with a grain of salt
+md5sums=(c5fd0d441a39b054a3968bf548db9f9a)
+
+# Version 0.28.0 won't build without this
+options=(!lto)
+
+# make install actually rebuilds everything. Yikes.
+# Thus the lack of a build() fucntion.
+package() {
+ gendesk -n --pkgname "$pkgname" --pkgdesc "$pkgdesc" \
+ --exec 'crawl-tiles' --name 'Dungeon Crawl Stone Soup' PKGBUILD
+
+ cd "stone_soup-${pkgver}/source"
+
+ sed -i 's/INSTALL_UGRP := games:games/INSTALL_UGRP := root:root/' Makefile
+
+ # first build and install tiles version
+
+ make DESTDIR="${pkgdir}" \
+ SAVEDIR="~/.crawl/" \
+ DATADIR="/usr/share/${pkgname}/data" \
+ TILES=y \
+ EXTERNAL_LDFLAGS="$LDFLAGS" \
+ prefix=/usr \
+ bin_prefix=bin \
+ install
+
+ # rename tiles executable to avoid clashing with console crawl
+
+ mv "${pkgdir}/usr/bin/crawl" "${pkgdir}/usr/bin/crawl-tiles"
+
+ # then build and install console version
+
+ make DESTDIR="${pkgdir}" \
+ SAVEDIR="~/.crawl/" \
+ DATADIR="/usr/share/${pkgname}/data" \
+ EXTERNAL_LDFLAGS="$LDFLAGS" \
+ prefix=/usr \
+ bin_prefix=bin \
+ install
+
+ # install crawl license
+
+ install -D -m644 ../LICENSE \
+ "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+
+ # install icon and .desktop file
+
+ install -D -m644 dat/tiles/stone_soup_icon-32x32.png \
+ "${pkgdir}/usr/share/pixmaps/${pkgname}.png"
+ install -D -m644 "${srcdir}/${pkgname}.desktop" \
+ "${pkgdir}/usr/share/applications/${pkgname}.desktop"
+}
Deleted: stone-soup.install
===================================================================
--- stone-soup.install 2022-03-03 01:45:07 UTC (rev 1140166)
+++ stone-soup.install 2022-03-03 01:45:08 UTC (rev 1140167)
@@ -1,11 +0,0 @@
-post_upgrade() {
-
- # return if old pkgver >= 0.9.0-2
- [[ $(vercmp $2 0.9.0-2) -ge 0 ]] && return
-
- echo "---------------------------------------------------------------------
- stone-soup saves have moved to ~/.crawl.
- If you want to keep your old saves, move ~/.stone-soup to
- ~/.crawl.
----------------------------------------------------------------------"
-}
More information about the arch-commits
mailing list