[arch-commits] Commit in kate/repos (testing-x86_64 testing-x86_64/PKGBUILD)

Antonio Rojas arojas at gemini.archlinux.org
Thu Mar 3 11:43:47 UTC 2022


    Date: Thursday, March 3, 2022 @ 11:43:47
  Author: arojas
Revision: 438557

archrelease: copy trunk to testing-x86_64

Added:
  kate/repos/testing-x86_64/
  kate/repos/testing-x86_64/PKGBUILD
    (from rev 438556, kate/trunk/PKGBUILD)

----------+
 PKGBUILD |   57 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)

Copied: kate/repos/testing-x86_64/PKGBUILD (from rev 438556, kate/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2022-03-03 11:43:47 UTC (rev 438557)
@@ -0,0 +1,57 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+
+pkgbase=kate
+pkgname=(kwrite kate)
+pkgver=21.12.3
+pkgrel=1
+arch=(x86_64)
+license=(GPL LGPL FDL)
+makedepends=(extra-cmake-modules kdoctools plasma-framework knewstuff kitemmodels ktexteditor kactivities kuserfeedback)
+source=(https://download.kde.org/stable/release-service/$pkgver/src/$pkgbase-$pkgver.tar.xz{,.sig})
+sha256sums=('afa5141fb2746fc18ea2d97bd80ec37c096589822fe0b0e7ec00c63d0198e0de'
+            'SKIP')
+validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid at kde.org>
+              F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87  # Christoph Feck <cfeck at kde.org>
+              D81C0CB38EB725EF6691C385BB463350D6EF31EF) # Heiko Becker <heiko.becker at kde.org>
+options=(debug)
+
+build() {
+  cmake -B build -S $pkgbase-$pkgver \
+    -DBUILD_TESTING=OFF
+  cmake --build build
+}
+
+package_kwrite() {
+  pkgdesc='Text Editor'
+  groups=(kde-applications kde-utilities)
+  url='https://apps.kde.org/kwrite/'
+  depends=(ktexteditor hicolor-icon-theme)
+
+  DESTDIR="$pkgdir" cmake --install build
+
+  find "$pkgdir" -type f -name '*kate*' -exec rm {} \;
+  rm -r "$pkgdir"/usr/lib/qt/plugins/ktexteditor \
+        "$pkgdir"/usr/share/doc/HTML/*/{kate,katepart} \
+        "$pkgdir"/usr/share/katexmltools \
+        "$pkgdir"/usr/share/locale/*/LC_MESSAGES/{ktexteditorpreviewplugin,lspclient,tabswitcherplugin}.mo \
+        "$pkgdir"/usr/share/plasma/plasmoids
+}
+
+package_kate() {
+  pkgdesc='Advanced Text Editor'
+  groups=(kde-applications kde-utilities)
+  url='https://apps.kde.org/kate/'
+  depends=(knewstuff ktexteditor kactivities kuserfeedback hicolor-icon-theme)
+  optdepends=('konsole: open a terminal in Kate'
+              'clang: C and C++ LSP support'
+              'python-lsp-server: Python LSP support'
+              'texlab: LaTeX LSP support'
+              'rust: Rust LSP support'
+              'git: git-blame plugin')
+  DESTDIR="$pkgdir" cmake --install build
+
+  find "$pkgdir" -type f -name '*kwrite*' -exec rm {} \;
+  rm -r "$pkgdir"/usr/share/doc/HTML/*/kwrite
+}



More information about the arch-commits mailing list