[arch-commits] Commit in intel-compute-runtime/repos (2 files)

[Bruno Pagani]

    Date: Saturday, March 5, 2022 @ 09:52:38
  Author: archange
Revision: 1142156

archrelease: copy trunk to community-staging-x86_64

Added:
  intel-compute-runtime/repos/community-staging-x86_64/
  intel-compute-runtime/repos/community-staging-x86_64/PKGBUILD
    (from rev 1142155, intel-compute-runtime/trunk/PKGBUILD)

----------+
 PKGBUILD |   41 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 41 insertions(+)

Copied: intel-compute-runtime/repos/community-staging-x86_64/PKGBUILD (from rev 1142155, intel-compute-runtime/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-03-05 09:52:38 UTC (rev 1142156)
@@ -0,0 +1,41 @@
+# Maintainer: Daniel Bermond <dbermond at archlinux.org>
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+
+pkgname=intel-compute-runtime
+pkgver=22.09.22577
+pkgrel=1
+pkgdesc="Intel(R) Graphics Compute Runtime for oneAPI Level Zero and OpenCL(TM) Driver"
+arch=(x86_64)
+url="https://01.org/compute-runtime"
+license=(MIT)
+depends=(gcc-libs intel-gmmlib intel-graphics-compiler)
+makedepends=(cmake libva level-zero-headers igsc)
+optdepends=('libva: for cl_intel_va_api_media_sharing'
+            'libdrm: for cl_intel_va_api_media_sharing')
+provides=(opencl-driver level-zero-driver)
+options=(!lto)
+source=(https://github.com/intel/compute-runtime/archive/${pkgver}/${pkgname}-${pkgver}.tar.gz)
+sha256sums=('5e8dd1e740e04298563ae3e8b73375d9b441a9c6bcd10a8f4d867d101d8dd26b')
+
+build() {
+  # ${${pkgver#*.}%.*} not supported by bash?
+  cmake -B build -S compute-runtime-${pkgver} \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_INSTALL_LIBDIR=lib \
+    -DNEO_OCL_VERSION_MAJOR=${pkgver%%.*} \
+    -DNEO_OCL_VERSION_MINOR=$(echo ${pkgver} | cut -d . -f2) \
+    -DNEO_VERSION_BUILD=${pkgver##*.} \
+    -DSUPPORT_DG1=ON \
+    -DSKIP_UNIT_TESTS=1 \
+    -Wno-dev
+  make -C build
+}
+
+package() {
+  make -C build DESTDIR="${pkgdir}" install
+  install -Dm755 build/bin/libocloc.so -t "${pkgdir}"/usr/lib/intel-opencl
+  install -Dm644 compute-runtime-${pkgver}/LICENSE.md -t "${pkgdir}"/usr/share/licenses/${pkgname}
+  
+  ln -s $(find "${pkgdir}"/usr/lib -regex '.*libze_intel_gpu.so.[0-9]*' -exec basename {} \;) "${pkgdir}"/usr/lib/libze_intel_gpu.so
+}