[arch-commits] Commit in deepin-file-manager/repos (2 files)

[Antonio Rojas]

    Date: Saturday, March 5, 2022 @ 11:54:37
  Author: arojas
Revision: 1142176

archrelease: copy trunk to community-testing-x86_64

Added:
  deepin-file-manager/repos/community-testing-x86_64/
  deepin-file-manager/repos/community-testing-x86_64/PKGBUILD
    (from rev 1142175, deepin-file-manager/trunk/PKGBUILD)

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Copied: deepin-file-manager/repos/community-testing-x86_64/PKGBUILD (from rev 1142175, deepin-file-manager/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2022-03-05 11:54:37 UTC (rev 1142176)
@@ -0,0 +1,47 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Josip Ponjavic <josipponjavic at gmail dot com>
+# Contributor: Xu Fasheng <fasheng.xu[AT]gmail.com>
+
+pkgname=deepin-file-manager
+pkgver=5.5.3
+pkgrel=2
+epoch=1
+pkgdesc='Deepin File Manager'
+arch=('x86_64')
+url="https://github.com/linuxdeepin/dde-file-manager"
+license=('GPL3')
+# startdde: for com.deepin.SessionManager
+depends=('deepin-qt5integration' 'deepin-anything' 'disomaster' 'docparser' 'file' 'gio-qt'
+         'libmediainfo' 'lucene++' 'avfs' 'polkit-qt5' 'poppler' 'ffmpegthumbnailer' 'jemalloc'
+         'kcodecs' 'startdde' 'taglib' 'htmlcxx' 'libgsf' 'mimetic' 'boost-libs')
+makedepends=('boost' 'qt5-tools' 'deepin-dock' 'deepin-movie' 'deepin-gettext-tools')
+optdepends=('deepin-manual: for help menual'
+            'deepin-shortcut-viewer: for shortcut display'
+            'deepin-screensaver: for screensaver chooser'
+            'deepin-movie: for video preview'
+            'deepin-terminal: for opening in terminal'
+            'deepin-compressor: for compress/decompress')
+groups=('deepin')
+provides=('deepin-desktop')
+conflicts=('deepin-desktop')
+replaces=('deepin-desktop')
+source=("https://github.com/linuxdeepin/dde-file-manager/archive/$pkgver/$pkgname-$pkgver.tar.gz")
+sha512sums=('6174369b79994c64cefb4808f4b6d47d2847f02907a6843280b699bbcbb2e71ae6abcdcdd7d4b642e2b20c6ca54cc985d03781c5b1521c2045375fc4a8cd2fc9')
+
+prepare() {
+  cd dde-file-manager-$pkgver
+  sed -e 's|systembusconf.path = /etc/dbus-1/system.d|systembusconf.path = /usr/share/dbus-1/system.d|' \
+      -e 's|systemd_service.path = /lib/systemd/system|systemd_service.path = /usr/lib/systemd/system|' \
+      -i src/dde-file-manager-daemon/dde-file-manager-daemon.pro
+}
+
+build() {
+  cd dde-file-manager-$pkgver
+  qmake-qt5 PREFIX=/usr filemanager.pro
+  make
+}
+
+package() {
+  cd dde-file-manager-$pkgver
+  make INSTALL_ROOT="$pkgdir" install
+}