[arch-commits] Commit in openimageio/repos (2 files)

[Sven-Hendrik Haase]

    Date: Sunday, March 6, 2022 @ 02:10:43
  Author: svenstaro
Revision: 1142265

archrelease: copy trunk to community-staging-x86_64

Added:
  openimageio/repos/community-staging-x86_64/
  openimageio/repos/community-staging-x86_64/PKGBUILD
    (from rev 1142264, openimageio/trunk/PKGBUILD)

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Copied: openimageio/repos/community-staging-x86_64/PKGBUILD (from rev 1142264, openimageio/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-03-06 02:10:43 UTC (rev 1142265)
@@ -0,0 +1,47 @@
+# Maintainer: Sven-Hendrik Haase <svenstaro at archlinux.org>
+# Contributor: SpepS <dreamspepser at yahoo dot it>
+
+pkgname=openimageio
+pkgver=2.3.13.0
+pkgrel=1
+pkgdesc="A library for reading and writing images, including classes, utilities, and applications"
+arch=(x86_64)
+url="http://www.openimageio.org/"
+license=('custom')
+depends=('openexr' 'boost-libs' 'openjpeg2' 'glew' 'libtiff' 'opencolorio' 'libpng' 'libraw' 'libwebp'
+         'fmt' 'pugixml' 'pybind11' 'libheif' 'hdf5' 'freetype2')
+# TODO: Consider adding these deps: 'openvdb' 'ffmpeg' 'ptex' 'opencv'
+makedepends=('cmake' 'qt5-base' 'python' 'boost' 'mesa' 'fontconfig' 'libxrender' 'ninja' 'robin-map')
+optdepends=('qt5-base: iv image viewer'
+            'python: bindings support')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/OpenImageIO/oiio/archive/refs/tags/v$pkgver.tar.gz")
+sha512sums=('fbefa341a11fd502ec9313ca48a0fe433c5822699e4934f6a14089f670314cbe1c9c0b9a491b1d1927bda0223e38a62192c6ddeec6c4c5e6215a8b3fb6900dd8')
+
+build() {
+  cd oiio-$pkgver
+
+  cmake \
+    -Bbuild \
+    -GNinja \
+    -DUSE_PYTHON=ON \
+    -DPYTHON_VERSION=3.10 \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_INSTALL_LIBDIR=lib \
+    -DOIIO_BUILD_TESTS=ON \
+    -DOIIO_BUILD_TOOLS=ON \
+    -DBUILD_MISSING_FMT=OFF \
+    -DUSE_EXTERNAL_PUGIXML=ON \
+    -DSTOP_ON_WARNING=OFF
+  ninja -C build
+}
+
+package() {
+  cd oiio-$pkgver
+
+  DESTDIR="$pkgdir" ninja -C build install
+
+  # Remove vendored fonts
+  rm -r "$pkgdir"/usr/share/fonts
+
+  install -Dm644 LICENSE.md "$pkgdir/usr/share/licenses/$pkgname/LICENSE".md
+}