[arch-commits] Commit in cereal/repos (2 files)

[Felix Yan]

    Date: Sunday, March 6, 2022 @ 15:33:13
  Author: felixonmars
Revision: 1142394

archrelease: copy trunk to community-staging-any

Added:
  cereal/repos/community-staging-any/
  cereal/repos/community-staging-any/PKGBUILD
    (from rev 1142393, cereal/trunk/PKGBUILD)

----------+
 PKGBUILD |   41 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 41 insertions(+)

Copied: cereal/repos/community-staging-any/PKGBUILD (from rev 1142393, cereal/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2022-03-06 15:33:13 UTC (rev 1142394)
@@ -0,0 +1,41 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+
+pkgname=cereal
+pkgver=1.3.1
+pkgrel=2
+pkgdesc='C++11 library for serialization'
+arch=(any)
+url=https://github.com/USCiLab/cereal
+license=(BSD)
+makedepends=(
+  boost
+  cmake
+  git
+  ninja
+)
+_tag=1de8fe89471d69ea392ea260ce74e079d5f4b415
+source=(git+https://github.com/USCiLab/cereal.git#tag=${_tag})
+sha256sums=(SKIP)
+
+pkgver() {
+  cd cereal
+  git describe --tags | sed 's/^v//'
+}
+
+build() {
+  cmake -S cereal -B build -G Ninja \
+    -DCMAKE_BUILD_TYPE='' \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DSKIP_PORTABILITY_TEST=ON \
+    -DTHREAD_SAFE=ON \
+    -DWITH_WERROR=OFF
+  cmake --build build
+}
+
+package() {
+  DESTDIR="${pkgdir}" cmake --install build
+  install -Dm644 ${pkgname}/LICENSE -t "${pkgdir}"/usr/share/licenses/${pkgname}
+}
+
+# vim: ts=2 sw=2 et: