[arch-commits] Commit in lib32-zeromq/repos (3 files)

[Evangelos Foutras]

    Date: Sunday, March 6, 2022 @ 15:33:18
  Author: foutrelis
Revision: 1142396

archrelease: copy trunk to multilib-staging-x86_64

Added:
  lib32-zeromq/repos/multilib-staging-x86_64/
  lib32-zeromq/repos/multilib-staging-x86_64/PKGBUILD
    (from rev 1142395, lib32-zeromq/trunk/PKGBUILD)
  lib32-zeromq/repos/multilib-staging-x86_64/lib32-zeromq-openpgm.patch
    (from rev 1142395, lib32-zeromq/trunk/lib32-zeromq-openpgm.patch)

----------------------------+
 PKGBUILD                   |   65 +++++++++++++++++++++++++++++++++++++++++++
 lib32-zeromq-openpgm.patch |   23 +++++++++++++++
 2 files changed, 88 insertions(+)

Copied: lib32-zeromq/repos/multilib-staging-x86_64/PKGBUILD (from rev 1142395, lib32-zeromq/trunk/PKGBUILD)
===================================================================
--- multilib-staging-x86_64/PKGBUILD	                        (rev 0)
+++ multilib-staging-x86_64/PKGBUILD	2022-03-06 15:33:18 UTC (rev 1142396)
@@ -0,0 +1,65 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: Colm Hickey <colmohici at gmail.com>
+# Contributor: Kyle Keen <keenerd at gmail.com>
+
+pkgname=lib32-zeromq
+pkgver=4.3.4
+pkgrel=2
+pkgdesc='Fast messaging system built on sockets'
+arch=(x86_64)
+url=https://www.zeromq.org
+license=(LGPL)
+depends=(
+  lib32-gcc-libs
+  lib32-glibc
+  lib32-libpgm
+  lib32-libsodium
+  zeromq
+)
+makedepends=(
+  cmake
+  git
+  ninja
+  xmlto
+)
+_tag=7824f6762fa526c5bfb0baa23a6839ecf5988e91
+source=(
+  git+https://github.com/zeromq/libzmq.git?signed#tag=${_tag}
+  lib32-zeromq-openpgm.patch
+)
+validpgpkeys=(A9EA9081724FFAE0484C35A1A81CEA22BC8C7E2E) # Luca Boccassi <luca.boccassi at gmail.com>
+sha256sums=('SKIP'
+            '59d3b09f15096fee4effb1916d0788243f41f6a0aa166ae53a8d876abc63fc48')
+
+prepare() {
+  cd libzmq
+  patch -Np1 -i ../lib32-zeromq-openpgm.patch
+}
+
+pkgver() {
+  cd libzmq
+  git describe --tags | sed 's/^v//'
+}
+
+build() {
+  export CC='gcc -m32'
+  export CXX='g++ -m32'
+  export CXXFLAGS+=' -Wno-unused-function'
+  export PKG_CONFIG=i686-pc-linux-gnu-pkg-config
+  cmake -S libzmq -B build -G Ninja \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_INSTALL_LIBDIR=lib32 \
+    -DWITH_DOC=OFF \
+    -DWITH_LIBSODIUM=ON \
+    -DWITH_OPENPGM=ON \
+    -DWITH_TLS=OFF \
+    -Wno-dev
+  cmake --build build
+}
+
+package() {
+  DESTDIR="${pkgdir}" cmake --install build
+  rm -rf "${pkgdir}"/usr/{bin,include,share}
+}
+
+# vim: ts=2 sw=2 et:

Copied: lib32-zeromq/repos/multilib-staging-x86_64/lib32-zeromq-openpgm.patch (from rev 1142395, lib32-zeromq/trunk/lib32-zeromq-openpgm.patch)
===================================================================
--- multilib-staging-x86_64/lib32-zeromq-openpgm.patch	                        (rev 0)
+++ multilib-staging-x86_64/lib32-zeromq-openpgm.patch	2022-03-06 15:33:18 UTC (rev 1142396)
@@ -0,0 +1,23 @@
+diff '--color=auto' -rupN libzmq.orig/CMakeLists.txt libzmq/CMakeLists.txt
+--- libzmq.orig/CMakeLists.txt	2021-05-06 16:35:11.594304700 +0200
++++ libzmq/CMakeLists.txt	2021-05-06 16:42:05.666080883 +0200
+@@ -793,7 +793,7 @@ else()
+     # message(FATAL_ERROR "WITH_OPENPGM not implemented")
+ 
+     if(NOT OPENPGM_PKGCONFIG_NAME)
+-      set(OPENPGM_PKGCONFIG_NAME "openpgm-5.2")
++      set(OPENPGM_PKGCONFIG_NAME "openpgm-5.3")
+     endif()
+ 
+     set(OPENPGM_PKGCONFIG_NAME
+@@ -1447,6 +1447,10 @@ if(BUILD_SHARED)
+     endif()
+   endif()
+ 
++  if(OPENPGM_FOUND)
++    target_link_libraries(libzmq ${OPENPGM_LIBRARIES})
++  endif()
++
+   if(HAVE_WS2_32)
+     target_link_libraries(libzmq ws2_32)
+   elseif(HAVE_WS2)