[arch-commits] Commit in musescore/repos (2 files)

[Evangelos Foutras]

    Date: Sunday, March 6, 2022 @ 15:33:53
  Author: foutrelis
Revision: 1142403

archrelease: copy trunk to community-staging-x86_64

Added:
  musescore/repos/community-staging-x86_64/
  musescore/repos/community-staging-x86_64/PKGBUILD
    (from rev 1142401, musescore/trunk/PKGBUILD)

----------+
 PKGBUILD |   77 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 77 insertions(+)

Copied: musescore/repos/community-staging-x86_64/PKGBUILD (from rev 1142401, musescore/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-03-06 15:33:53 UTC (rev 1142403)
@@ -0,0 +1,77 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: Stefan Husmann <stefan-husmann at t-online.de>
+# Contributor: Cristian Maureira <saint at archlinux.cl>
+# Contributor: Dr.Egg <rwhite at archlinux.us>
+
+pkgname=musescore
+pkgver=3.6.2
+pkgrel=4
+pkgdesc='Create, play and print beautiful sheet music'
+arch=(x86_64)
+url=https://musescore.org/
+license=(GPL)
+groups=(pro-audio)
+depends=(
+  alsa-lib
+  freetype2
+  libpulse
+  libsndfile
+  libvorbisfile.so
+  libportaudio.so
+  libportmidi.so
+  qt5-base
+  qt5-declarative
+  qt5-graphicaleffects
+  qt5-quickcontrols
+  qt5-quickcontrols2
+  qt5-svg
+  qt5-tools
+  qt5-webengine
+  qt5-xmlpatterns
+  zlib
+)
+makedepends=(
+  cmake
+  doxygen
+  git
+  lame
+  qt5-script
+  texlive-core
+)
+optdepends=('lame: MP3 export')
+_tag=3224f342d12f4af8ea782e929c49f5ce85f97da6
+source=(git+https://github.com/musescore/MuseScore.git#tag=${_tag})
+sha256sums=(SKIP)
+
+prepare() {
+  cd MuseScore
+  git cherry-pick -n 63d8b7ee90e9ec6604e334a3ebb12fced7fab36d
+}
+
+pkgver() {
+  cd MuseScore
+  git describe --tags | sed 's/^v//'
+}
+
+build() {
+  cmake -S MuseScore -B build \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_SKIP_RPATH=ON \
+    -DBUILD_CRASH_REPORTER=OFF \
+    -DBUILD_TELEMETRY_MODULE=OFF \
+    -DBUILD_WEBENGINE=OFF \
+    -DDOWNLOAD_SOUNDFONT=OFF \
+    -DMUSESCORE_BUILD_CONFIG=release \
+    -DMUSESCORE_REVISION=$(git rev-parse --short=7 HEAD) \
+    -DPACKAGE_FILE_ASSOCIATION=ON \
+    -DUSE_SYSTEM_FREETYPE=ON \
+    -Wno-dev
+  make -j1 lrelease manpages -C build;
+  make -C build;
+}
+
+package() {
+  make DESTDIR="${pkgdir}" install -C build
+}
+
+# vim: ts=2 sw=2 et: