[arch-commits] Commit in libass/repos (staging-x86_64 staging-x86_64/PKGBUILD)
Evangelos Foutras
foutrelis at gemini.archlinux.org
Sun Mar 6 15:35:37 UTC 2022
Date: Sunday, March 6, 2022 @ 15:35:37
Author: foutrelis
Revision: 439062
archrelease: copy trunk to staging-x86_64
Added:
libass/repos/staging-x86_64/
libass/repos/staging-x86_64/PKGBUILD
(from rev 439061, libass/trunk/PKGBUILD)
----------+
PKGBUILD | 57 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 57 insertions(+)
Copied: libass/repos/staging-x86_64/PKGBUILD (from rev 439061, libass/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD (rev 0)
+++ staging-x86_64/PKGBUILD 2022-03-06 15:35:37 UTC (rev 439062)
@@ -0,0 +1,57 @@
+# Maintainer: Giovanni Scafora <giovanni at archlinux.org>
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: G_Syme <demichan at mail.upb.de>
+
+pkgname=libass
+pkgver=0.15.2
+pkgrel=2
+pkgdesc='A portable library for SSA/ASS subtitles rendering'
+arch=(x86_64)
+url=https://github.com/libass/libass/
+license=(BSD)
+depends=(
+ fontconfig
+ fribidi
+ glib2
+ glibc
+ harfbuzz
+ libfreetype.so
+)
+makedepends=(
+ git
+ nasm
+)
+provides=(libass.so)
+_tag=c967a5a3d9ec0d36af1148b3fdf2f307a21dd122
+source=(git+https://github.com/libass/libass.git#tag=${_tag})
+validpgpkeys=(5458C3100671F252B0F4C7708079D18C21AAAAFF) # Oleg Oshmyan (Chortos-2) <chortos at inbox.lv>
+b2sums=(SKIP)
+
+pkgver() {
+ cd libass
+
+ git describe --tags
+}
+
+prepare() {
+ cd libass
+
+ ./autogen.sh
+}
+
+build() {
+ cd libass
+
+ ./configure \
+ --prefix=/usr \
+ --enable-harfbuzz \
+ --enable-fontconfig
+ make
+}
+
+package() {
+ make DESTDIR="${pkgdir}" -C libass install
+ install -Dm 644 libass/COPYING -t "${pkgdir}"/usr/share/licenses/libass/
+}
+
+# vim: ts=2 sw=2 et:
More information about the arch-commits
mailing list