[arch-commits] Commit in rbutil/repos (2 files)

[Evangelos Foutras]

    Date: Sunday, March 6, 2022 @ 15:37:20
  Author: foutrelis
Revision: 1142428

archrelease: copy trunk to community-staging-x86_64

Added:
  rbutil/repos/community-staging-x86_64/
  rbutil/repos/community-staging-x86_64/PKGBUILD
    (from rev 1142427, rbutil/trunk/PKGBUILD)

----------+
 PKGBUILD |   61 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 61 insertions(+)

Copied: rbutil/repos/community-staging-x86_64/PKGBUILD (from rev 1142427, rbutil/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-03-06 15:37:20 UTC (rev 1142428)
@@ -0,0 +1,61 @@
+# Maintainer: Maxime Gauduin <alucryd at gmail.com>
+# Contributor: David Runge <dvzrv at archlinux.org>
+# Contributor: said <atvordhosbn at gmail.com>
+# Contributor: clinx <clinx.hacker at googlemail.com>
+
+_name=rockbox
+pkgname=rbutil
+pkgver=1.4.1.r381.g94eb1df58b
+pkgrel=3
+pkgdesc='Rockbox Utility'
+arch=(x86_64)
+url=https://www.rockbox.org/twiki/bin/view/Main/RockboxUtility
+license=(GPL)
+depends=(
+  crypto++
+  qt5-base
+  qt5-multimedia
+  libxkbcommon-x11
+  zlib
+)
+makedepends=(
+  gendesk
+  git
+  libusb
+  qt5-tools
+)
+optdepends=('speex: voice files support')
+# NOTE: commit with latest Qt fixes
+_commit=94eb1df58b
+# NOTE: using git sources, as the build fails during linking with 1.4.1
+source=("git+https://git.${_name}.org/cgit/${_name}.git#commit=${_commit}")
+sha256sums=('SKIP')
+
+prepare() {
+  gendesk -n --pkgname "${pkgname}" --pkgdesc "${pkgdesc}" --name="Rockbox Utility" --exec="RockboxUtility" --categories="Application;Utility;" --comment="Rockbox automated installer"
+}
+
+pkgver() {
+  cd "${_name}"
+  git describe --long --exclude '*archos_retired*' --tags | sed 's/\([^-]*-g\)/r\1/;s/rbutil_//;s/-/./g'
+}
+
+build() {
+  cd "${_name}/${pkgname}/rbutilqt"
+
+  lrelease-qt5 rbutilqt.pro
+  qmake-qt5
+  make
+}
+
+package(){
+  depends+=('libusb-1.0.so')
+  cd "${_name}/${pkgname}/rbutilqt"
+
+  install -dm 755 "${pkgdir}"/usr/{bin,share/{applications,pixmaps}}
+  install -m 755 {,"${pkgdir}"/usr/bin/}RockboxUtility
+  install -m 644 icons/rockbox-256.png "${pkgdir}"/usr/share/pixmaps/rbutil.png
+  install -m 644 {"${srcdir}","${pkgdir}"/usr/share/applications}/rbutil.desktop
+}
+
+# vim: ts=2 sw=2 et: