[arch-commits] Commit in libvorbis/repos (staging-x86_64 staging-x86_64/PKGBUILD)
Felix Yan
felixonmars at gemini.archlinux.org
Sun Mar 6 15:40:12 UTC 2022
Date: Sunday, March 6, 2022 @ 15:40:12
Author: felixonmars
Revision: 439066
archrelease: copy trunk to staging-x86_64
Added:
libvorbis/repos/staging-x86_64/
libvorbis/repos/staging-x86_64/PKGBUILD
(from rev 439065, libvorbis/trunk/PKGBUILD)
----------+
PKGBUILD | 57 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 57 insertions(+)
Copied: libvorbis/repos/staging-x86_64/PKGBUILD (from rev 439065, libvorbis/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD (rev 0)
+++ staging-x86_64/PKGBUILD 2022-03-06 15:40:12 UTC (rev 439066)
@@ -0,0 +1,57 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: Bartłomiej Piotrowski <bpiotrowski at archlinux.org>
+# Contributor: Tobias Kieslich <tobias at archlinux.org>
+# Contributor: dorphell <dorphell at archlinux.org>
+# Contributor: John Proctor <jproctor at prium.net>
+
+pkgname=libvorbis
+pkgver=1.3.7
+pkgrel=3
+pkgdesc='Reference implementation of the Ogg Vorbis audio format'
+arch=(x86_64)
+url=https://www.xiph.org/vorbis/
+license=(BSD)
+depends=(libogg.so)
+makedepends=(git)
+provides=(
+ libvorbis.so
+ libvorbisenc.so
+ libvorbisfile.so
+)
+_tag=0c55fa38933fd4bdb7db7c298b27e7bf2f2c5e98
+source=(git+https://github.com/xiph/vorbis.git?signed#tag=${_tag})
+validpgpkeys=(B7B00AEE1F960EEA0FED66FB9259A8F2D2D44C84) # Ralph Giles <giles at thaumas.net>
+sha256sums=(SKIP)
+
+pkgver() {
+ cd vorbis
+
+ git describe --tags | sed 's/^v//'
+}
+
+prepare() {
+ cd vorbis
+
+ ./autogen.sh
+}
+
+build() {
+ cd vorbis
+
+ ./configure \
+ --prefix=/usr \
+ --disable-static \
+ --enable-shared
+ make
+}
+
+check() {
+ make -C vorbis check
+}
+
+package() {
+ make DESTDIR="${pkgdir}" -C vorbis install
+ install -Dm 644 vorbis/COPYING -t "${pkgdir}"/usr/share/licenses/libvorbis
+}
+
+# vim: ts=2 sw=2 et:
More information about the arch-commits
mailing list