[arch-commits] Commit in breezy/repos (staging-x86_64 staging-x86_64/PKGBUILD)

[Felix Yan]

    Date: Sunday, March 6, 2022 @ 15:43:00
  Author: felixonmars
Revision: 439070

archrelease: copy trunk to staging-x86_64

Added:
  breezy/repos/staging-x86_64/
  breezy/repos/staging-x86_64/PKGBUILD
    (from rev 439069, breezy/trunk/PKGBUILD)

----------+
 PKGBUILD |   60 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 60 insertions(+)

Copied: breezy/repos/staging-x86_64/PKGBUILD (from rev 439069, breezy/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2022-03-06 15:43:00 UTC (rev 439070)
@@ -0,0 +1,60 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: Adam Fontenot <adam.m.fontenot at gmail.com>
+
+pkgname=breezy
+pkgver=3.2.1
+pkgrel=2
+pkgdesc='A decentralized revision control system with support for Bazaar and Git file formats'
+arch=(x86_64)
+url=https://www.breezy-vcs.org/
+license=(GPL2)
+depends=(
+  python-configobj
+  python-patiencediff
+  python-six
+)
+makedepends=(
+  cython
+  git
+  python-dulwich
+  python-fastimport
+  python-gpgme
+  python-paramiko
+  python-setuptools
+)
+checkdepends=(python-testrepository)
+optdepends=(
+  'python-dulwich: Git support'
+  'python-fastimport: Fastimport support'
+  'python-gpgme: PGP support'
+  'python-paramiko: access branches over SFTP'
+)
+provides=(bzr)
+conflicts=(bzr)
+replaces=(bzr)
+_tag=ebbce920e284a8cb13aba796f5592470ddd132ab
+source=(git+https://github.com/breezy-team/breezy.git#tag=${_tag})
+sha256sums=(SKIP)
+
+prepare() {
+  cd breezy
+  sed 's/_script_version = (3, 2, 0)/_script_version = (3, 2, 1)/' -i brz
+}
+
+pkgver() {
+  cd breezy
+  git describe --tags | sed 's/brz-//; s/-/./g'
+}
+
+build() {
+  cd breezy
+  python setup.py build
+}
+
+package() {
+  cd breezy
+  python setup.py install --root="${pkgdir}" --install-data=usr/share --optimize=1 --skip-build
+  ln -s brz "${pkgdir}"/usr/bin/bzr # backwards compatibility
+}
+
+# vim: ts=2 sw=2 et: