[arch-commits] Commit in lttng-ust2.12/repos (2 files)

[Felix Yan]

    Date: Sunday, March 6, 2022 @ 15:46:15
  Author: felixonmars
Revision: 1142521

archrelease: copy trunk to community-staging-x86_64

Added:
  lttng-ust2.12/repos/community-staging-x86_64/
  lttng-ust2.12/repos/community-staging-x86_64/PKGBUILD
    (from rev 1142519, lttng-ust2.12/trunk/PKGBUILD)

----------+
 PKGBUILD |   54 ++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)

Copied: lttng-ust2.12/repos/community-staging-x86_64/PKGBUILD (from rev 1142519, lttng-ust2.12/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-03-06 15:46:15 UTC (rev 1142521)
@@ -0,0 +1,54 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: Thore Bödecker <foxxx0 at archlinux.org>
+# Contributor: Philippe Proulx <pproulx at efficios.com>
+# Contributor: Manuel Mendez <mmendez534 at gmail dot com>
+
+pkgname=lttng-ust2.12
+pkgver=2.12.0
+pkgrel=3
+pkgdesc='LTTng user space tracing libraries for LTTng'
+arch=(x86_64)
+url=https://lttng.org/
+license=(
+  LGPL2.1
+  GPL2
+  MIT
+)
+depends=(
+  glibc
+  libnuma.so
+  liburcu
+)
+makedepends=(git)
+conflicts=(lttng-ust)
+_tag=f907545e84b940f9648edcf308a80bd79c5a3756
+source=(git+https://github.com/lttng/lttng-ust.git?signed#tag=${_tag})
+b2sums=(SKIP)
+validpgpkeys=(2A0B4ED915F2D3FA45F5B16217280A9781186ACF) # Mathieu Desnoyers <mathieu.desnoyers at efficios.com>
+
+prepare() {
+  cd lttng-ust
+  autoreconf -fiv
+}
+
+pkgver() {
+  cd lttng-ust
+  git describe --tags | sed 's/^v//'
+}
+
+build() {
+  cd lttng-ust
+  ./configure \
+    --prefix=/usr \
+    --disable-examples \
+    --disable-man-pages
+  make
+}
+
+package() {
+  cd lttng-ust
+  make DESTDIR="${pkgdir}" install
+  install -Dm 644 LICENSE -t "${pkgdir}"/usr/share/licenses/lttng-ust2.12/
+}
+
+# vim: ts=2 sw=2 et: