[arch-commits] Commit in rgbds/repos (2 files)
Evangelos Foutras
foutrelis at gemini.archlinux.org
Sun Mar 6 15:48:22 UTC 2022
Date: Sunday, March 6, 2022 @ 15:48:21
Author: foutrelis
Revision: 1142543
archrelease: copy trunk to community-staging-x86_64
Added:
rgbds/repos/community-staging-x86_64/
rgbds/repos/community-staging-x86_64/PKGBUILD
(from rev 1142542, rgbds/trunk/PKGBUILD)
----------+
PKGBUILD | 43 +++++++++++++++++++++++++++++++++++++++++++
1 file changed, 43 insertions(+)
Copied: rgbds/repos/community-staging-x86_64/PKGBUILD (from rev 1142542, rgbds/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD (rev 0)
+++ community-staging-x86_64/PKGBUILD 2022-03-06 15:48:21 UTC (rev 1142543)
@@ -0,0 +1,43 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: Vaporeon <vaporeon at vaporeon.io>
+
+pkgname=rgbds
+pkgver=0.5.2
+pkgrel=2
+pkgdesc='Rednex GameBoy Development System'
+arch=(x86_64)
+url=https://github.com/rednex/rgbds/
+license=(MIT)
+depends=(
+ glibc
+ libpng
+)
+makedepends=(
+ cmake
+ git
+ ninja
+)
+_tag=9d993d84e85eeb8dd304e48463d89865795e97ed
+source=(git+https://github.com/rednex/rgbds.git#tag=${_tag})
+sha256sums=(SKIP)
+
+pkgver() {
+ cd rgbds
+
+ git describe --tags | sed 's/^v//'
+}
+
+build() {
+ cmake -S rgbds -B build -G Ninja \
+ -DCMAKE_BUILD_TYPE=None \
+ -DCMAKE_INSTALL_PREFIX=/usr
+ ninja -C build
+}
+
+package() {
+ DESTDIR="${pkgdir}" ninja -C build install
+ install -Dm 644 rgbds/LICENSE -t "${pkgdir}"/usr/share/licenses/rgbds/
+ find rgbds/contrib/zsh_compl -type f -exec install -Dm 644 {} -t "${pkgdir}"/usr/share/zsh/site-functions/ \;
+}
+
+# vim: ts=2 sw=2 et:
More information about the arch-commits
mailing list