[arch-commits] Commit in libva/repos (staging-x86_64 staging-x86_64/PKGBUILD)

[Evangelos Foutras]

    Date: Sunday, March 6, 2022 @ 15:50:07
  Author: foutrelis
Revision: 439086

archrelease: copy trunk to staging-x86_64

Added:
  libva/repos/staging-x86_64/
  libva/repos/staging-x86_64/PKGBUILD
    (from rev 439085, libva/trunk/PKGBUILD)

----------+
 PKGBUILD |   64 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 64 insertions(+)

Copied: libva/repos/staging-x86_64/PKGBUILD (from rev 439085, libva/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2022-03-06 15:50:07 UTC (rev 439086)
@@ -0,0 +1,64 @@
+# Maintainer: Maxime Gauduin <alucryd at archlonux.org>
+# Contributor: Bartłomiej Piotrowski <bpiotrowski at archlinux.org>
+# Contributor: Ionut Biru <ibiru at archlinux.org>
+
+pkgname=libva
+pkgver=2.13.0
+pkgrel=2
+pkgdesc='Video Acceleration (VA) API for Linux'
+arch=(x86_64)
+url=https://01.org/linuxmedia/vaapi
+license=(MIT)
+depends=(
+  libdrm
+  libgl
+  libx11
+  libxext
+  libxfixes
+  wayland
+)
+makedepends=(
+  git
+  libglvnd
+  mesa
+  meson
+)
+optdepends=(
+  'intel-media-driver: backend for Intel GPUs (>= Broadwell)'
+  'libva-vdpau-driver: backend for Nvidia and AMD GPUs'
+  'libva-intel-driver: backend for Intel GPUs (<= Haswell)'
+)
+provides=(
+  libva-drm.so
+  libva-glx.so
+  libva-wayland.so
+  libva-x11.so
+  libva.so
+)
+backup=(etc/libva.conf)
+_tag=8d948cc076cb255b442afe4f0f4e04cbc80785bf
+source=(git+https://github.com/intel/libva.git#tag=${_tag})
+sha256sums=(SKIP)
+
+pkgver() {
+  cd libva
+
+  git describe --tags
+}
+
+build() {
+  CFLAGS+=" -DENABLE_VA_MESSAGING"  # Option missing
+  arch-meson libva build
+  ninja -C build
+}
+
+package() {
+  DESTDIR="${pkgdir}" meson install -C build
+  install -Dm 644 libva/COPYING -t "${pkgdir}"/usr/share/licenses/libva
+
+  install -Dm 644 /dev/stdin "${pkgdir}"/etc/libva.conf <<END
+LIBVA_MESSAGING_LEVEL=1
+END
+}
+
+# vim: ts=2 sw=2 et: