[arch-commits] Commit in hoel/repos (2 files)
Felix Yan
felixonmars at gemini.archlinux.org
Sun Mar 6 15:51:51 UTC 2022
Date: Sunday, March 6, 2022 @ 15:51:50
Author: felixonmars
Revision: 1142574
archrelease: copy trunk to community-staging-x86_64
Added:
hoel/repos/community-staging-x86_64/
hoel/repos/community-staging-x86_64/PKGBUILD
(from rev 1142572, hoel/trunk/PKGBUILD)
----------+
PKGBUILD | 56 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 56 insertions(+)
Copied: hoel/repos/community-staging-x86_64/PKGBUILD (from rev 1142572, hoel/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD (rev 0)
+++ community-staging-x86_64/PKGBUILD 2022-03-06 15:51:50 UTC (rev 1142574)
@@ -0,0 +1,56 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+
+pkgname=hoel
+pkgver=1.4.18
+pkgrel=2
+pkgdesc='C Database abstraction library with json based language'
+arch=(x86_64)
+url=https://github.com/babelouest/hoel
+license=(LGPL2.1)
+depends=(
+ glibc
+ jansson
+ liborcania.so
+ libyder.so
+)
+makedepends=(
+ cmake
+ doxygen
+ git
+ graphviz
+ mariadb-libs
+ ninja
+ postgresql-libs
+ sqlite
+)
+optdepends=(
+ 'postgresql-libs: PostgreSQL support'
+ 'mariadb-libs: MariaDB support'
+ 'sqlite: SQLite support'
+)
+provides=(libhoel.so)
+_tag=7dbdaabcc698b6d600598d8db4ec746fcd937b3e
+source=(git+https://github.com/babelouest/hoel.git#tag=${_tag})
+validpgpkeys=(8405B02FCC28EF9744C8F253FE82139440BD22B9) # Nicolas Mora <nicolas at babelouest.org>
+b2sums=(SKIP)
+
+pkgver() {
+ cd hoel
+ git describe --tags | sed 's/^v//'
+}
+
+build() {
+ cmake -S hoel -B build -G Ninja \
+ -DCMAKE_BUILD_TYPE=None \
+ -DCMAKE_INSTALL_PREFIX=/usr \
+ -DBUILD_HOEL_DOCUMENTATION=ON
+ ninja -C build doc
+}
+
+package() {
+ DESTDIR="${pkgdir}" ninja -C build install
+ install -dm 755 "${pkgdir}"/usr/share/doc/hoel
+ cp -dr --no-preserve=ownership hoel/doc/html "${pkgdir}"/usr/share/doc/hoel/
+}
+
+# vim: ts=2 sw=2 et:
More information about the arch-commits
mailing list