[arch-commits] Commit in svt-vp9/repos (2 files)

[Evangelos Foutras]

    Date: Sunday, March 6, 2022 @ 15:55:18
  Author: foutrelis
Revision: 1142603

archrelease: copy trunk to community-staging-x86_64

Added:
  svt-vp9/repos/community-staging-x86_64/
  svt-vp9/repos/community-staging-x86_64/PKGBUILD
    (from rev 1142602, svt-vp9/trunk/PKGBUILD)

----------+
 PKGBUILD |   46 ++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)

Copied: svt-vp9/repos/community-staging-x86_64/PKGBUILD (from rev 1142602, svt-vp9/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-03-06 15:55:18 UTC (rev 1142603)
@@ -0,0 +1,46 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: Thomas Schneider <maxmusterm at gmail.com>
+
+pkgname=svt-vp9
+pkgver=0.3.0
+pkgrel=2
+pkgdesc='Scalable Video Technology VP9 encoder'
+arch=(x86_64)
+url=https://github.com/OpenVisualCloud/SVT-VP9
+license=(BSD)
+depends=(glibc)
+makedepends=(
+  cmake
+  git
+  nasm
+  ninja
+)
+_tag=e1bbb77ed315f417002071e93789b366d9ff997e
+source=(git+https://github.com/OpenVisualCloud/SVT-VP9.git#tag=${_tag})
+md5sums=(SKIP)
+
+pkgver() {
+  cd SVT-VP9
+
+  git describe --tags | sed 's/^v//'
+}
+
+prepare() {
+  sed '/CMAKE_BUILD_TYPE Release/d' -i SVT-VP9/CMakeLists.txt
+}
+
+build() {
+  export LDFLAGS="$LDFLAGS -Wl,-z,noexecstack"
+  cmake -S SVT-VP9 -B build -G Ninja \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DBUILD_SHARED_LIBS=ON \
+    -DNATIVE=OFF
+  ninja -C build
+}
+
+package() {
+  DESTDIR="${pkgdir}" ninja -C build install
+  install -Dm 644 SVT-VP9/LICENSE.md -t "${pkgdir}"/usr/share/licenses/svt-vp9/
+}
+
+# vim: ts=2 sw=2 et: