[arch-commits] Commit in lib32-orc/repos (2 files)

[Evangelos Foutras]

    Date: Sunday, March 6, 2022 @ 15:55:54
  Author: foutrelis
Revision: 1142612

archrelease: copy trunk to multilib-staging-x86_64

Added:
  lib32-orc/repos/multilib-staging-x86_64/
  lib32-orc/repos/multilib-staging-x86_64/PKGBUILD
    (from rev 1142611, lib32-orc/trunk/PKGBUILD)

----------+
 PKGBUILD |   48 ++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

Copied: lib32-orc/repos/multilib-staging-x86_64/PKGBUILD (from rev 1142611, lib32-orc/trunk/PKGBUILD)
===================================================================
--- multilib-staging-x86_64/PKGBUILD	                        (rev 0)
+++ multilib-staging-x86_64/PKGBUILD	2022-03-06 15:55:54 UTC (rev 1142612)
@@ -0,0 +1,48 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+
+pkgname=lib32-orc
+pkgver=0.4.32
+pkgrel=2
+pkgdesc='The Oild Runtime Compiler'
+arch=(x86_64)
+url=https://gstreamer.freedesktop.org/modules/orc.html
+license=(custom)
+depends=(
+  lib32-glibc
+  orc
+)
+makedepends=(
+  git
+  gtk-doc
+  meson
+  valgrind-multilib
+)
+_tag=629864f073ae003e63c026c1de2407fec713cb53
+source=(git+https://gitlab.freedesktop.org/gstreamer/orc.git#tag=${_tag})
+sha256sums=(SKIP)
+
+pkgver() {
+  cd orc
+
+  git describe --tags
+}
+
+build() {
+  export CC='gcc -m32'
+  export CXX='g++ -m32'
+  export PKG_CONFIG_PATH=/usr/lib32/pkgconfig
+
+  arch-meson orc build \
+    --libdir=/usr/lib32
+  ninja -C build
+}
+
+package() {
+  DESTDIR="$pkgdir" ninja -C build install
+  rm -rf "${pkgdir}"/usr/{bin,include,share}
+
+  install -dm 755 "${pkgdir}"/usr/share/licenses
+  ln -s orc "${pkgdir}"/usr/share/licenses/lib32-orc
+}
+
+# vim: ts=2 sw=2 et: