[arch-commits] Commit in libretro-genesis-plus-gx/repos (2 files)

[Felix Yan]

    Date: Sunday, March 6, 2022 @ 15:57:48
  Author: felixonmars
Revision: 1142638

archrelease: copy trunk to community-staging-x86_64

Added:
  libretro-genesis-plus-gx/repos/community-staging-x86_64/
  libretro-genesis-plus-gx/repos/community-staging-x86_64/PKGBUILD
    (from rev 1142637, libretro-genesis-plus-gx/trunk/PKGBUILD)

----------+
 PKGBUILD |   46 ++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)

Copied: libretro-genesis-plus-gx/repos/community-staging-x86_64/PKGBUILD (from rev 1142637, libretro-genesis-plus-gx/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-03-06 15:57:48 UTC (rev 1142638)
@@ -0,0 +1,46 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: Johnathan Jenkins <twodopeshaggy at gmail.com>
+# Contributor: prettyvanilla <prettyvanilla at posteo.at>
+# Contributor: almostalive <almostalive2003 at gmail.com>
+
+pkgname=libretro-genesis-plus-gx
+pkgver=1882
+pkgrel=2
+pkgdesc='Sega MS/GG/MD/CD core'
+arch=(x86_64)
+url=https://github.com/libretro/Genesis-Plus-GX
+license=(BSD LGPL2.1)
+groups=(libretro)
+depends=(
+  libretro-core-info
+  libvorbis
+  zlib
+)
+makedepends=(
+  clang
+  git
+)
+_commit=7539777f67b998bc0396633a05d330accdfbd7b1
+source=(libretro-genesis-plus-gx::git+https://github.com/libretro/Genesis-Plus-GX.git#commit=${_commit})
+b2sums=(SKIP)
+
+pkgver() {
+  cd libretro-genesis-plus-gx
+  git rev-list --count HEAD
+}
+
+build() {
+  export CC=clang # FS#71188 - [libretro-genesis-plus-gx] segfaults when compiled with -O2
+  make \
+    SHARED_LIBVORBIS=1 \
+    SYSTEM_ZLIB=1 \
+    -C libretro-genesis-plus-gx \
+    -f Makefile.libretro
+}
+
+package() {
+  install -Dm 644 libretro-genesis-plus-gx/genesis_plus_gx_libretro.so -t "${pkgdir}"/usr/lib/libretro/
+  install -Dm 644 libretro-genesis-plus-gx/LICENSE.txt -t "${pkgdir}"/usr/share/licenses/libretro-genesis-plus-gx/
+}
+
+# vim: ts=2 sw=2 et: