[arch-commits] Commit in lib32-brotli/repos (2 files)

[Evangelos Foutras]

    Date: Sunday, March 6, 2022 @ 16:05:26
  Author: foutrelis
Revision: 1142701

archrelease: copy trunk to multilib-staging-x86_64

Added:
  lib32-brotli/repos/multilib-staging-x86_64/
  lib32-brotli/repos/multilib-staging-x86_64/PKGBUILD
    (from rev 1142699, lib32-brotli/trunk/PKGBUILD)

----------+
 PKGBUILD |   56 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)

Copied: lib32-brotli/repos/multilib-staging-x86_64/PKGBUILD (from rev 1142699, lib32-brotli/trunk/PKGBUILD)
===================================================================
--- multilib-staging-x86_64/PKGBUILD	                        (rev 0)
+++ multilib-staging-x86_64/PKGBUILD	2022-03-06 16:05:26 UTC (rev 1142701)
@@ -0,0 +1,56 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Lex Black <autumn-wind at web dot de>
+# Contributor: TingPing <tingping at tingping.se>
+# Contributor: Guillaume Horel <guillaume.horel at gmail.com>
+
+pkgname=lib32-brotli
+pkgver=1.0.9
+pkgrel=4
+pkgdesc='Brotli compression library'
+arch=(x86_64)
+license=(MIT)
+url=https://github.com/google/brotli
+depends=(
+  brotli
+  lib32-gcc-libs
+)
+makedepends=(
+  cmake
+  git
+)
+provides=(
+  libbrotli{common,dec,enc}.so
+)
+_tag=e61745a6b7add50d380cfd7d3883dd6c62fc2c71
+source=(git+https://github.com/google/brotli#tag=${_tag})
+sha256sums=(SKIP)
+
+pkgver() {
+  cd brotli
+
+  git describe --tags | sed 's/^v//'
+}
+
+build() {
+  export CC='gcc -m32'
+  export PKG_CONFIG_PATH=/usr/lib32/pkgconfig
+
+  cmake -S brotli -B build \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_INSTALL_LIBDIR=/usr/lib32
+  cmake --build build
+}
+
+check() {
+  cmake --build build --target test
+}
+
+package() {
+  DESTDIR="$pkgdir" cmake --install build
+  rm -rf "${pkgdir}"/usr/{bin,include,lib32/*.a}
+  install -dm 755 "${pkgdir}"/usr/share/licenses
+  ln -s brotli "${pkgdir}"/usr/share/licenses/lib32-brotli
+}
+
+# vim: ts=2 sw=2 et: