[arch-commits] Commit in lib32-gamemode/repos (2 files)
Evangelos Foutras
foutrelis at gemini.archlinux.org
Sun Mar 6 16:08:46 UTC 2022
Date: Sunday, March 6, 2022 @ 16:08:46
Author: foutrelis
Revision: 1142731
archrelease: copy trunk to multilib-staging-x86_64
Added:
lib32-gamemode/repos/multilib-staging-x86_64/
lib32-gamemode/repos/multilib-staging-x86_64/PKGBUILD
(from rev 1142729, lib32-gamemode/trunk/PKGBUILD)
----------+
PKGBUILD | 61 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 61 insertions(+)
Copied: lib32-gamemode/repos/multilib-staging-x86_64/PKGBUILD (from rev 1142729, lib32-gamemode/trunk/PKGBUILD)
===================================================================
--- multilib-staging-x86_64/PKGBUILD (rev 0)
+++ multilib-staging-x86_64/PKGBUILD 2022-03-06 16:08:46 UTC (rev 1142731)
@@ -0,0 +1,61 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: Ysblokje <ysblokje at gmail.com>
+# Contributor: Mark Wagie <mark.wagie at tutanota.com>
+
+pkgname=lib32-gamemode
+pkgver=1.6.1
+pkgrel=2
+pkgdesc='A daemon/lib combo that allows games to request a set of optimisations be temporarily applied to the host OS'
+arch=(x86_64)
+url=https://github.com/FeralInteractive/gamemode
+license=(BSD)
+depends=(
+ lib32-dbus
+ lib32-glibc
+ lib32-systemd
+)
+makedepends=(
+ git
+ meson
+)
+checkdepends=(appstream)
+provides=(
+ libgamemode.so
+ libgamemodeauto.so
+)
+_tag=b11d2912e280acb87d9ad114d6c7cd8846c4ef02
+source=(git+https://github.com/FeralInteractive/gamemode.git#tag=${_tag})
+b2sums=(SKIP)
+
+pkgver() {
+ cd gamemode
+
+ git describe --tags
+}
+
+build() {
+ export CC='gcc -m32'
+ export PKG_CONFIG_PATH=/usr/lib32/pkgconfig
+
+ arch-meson gamemode build \
+ --libdir /usr/lib32 \
+ -Dwith-examples=false \
+ -Dwith-pam-group=gamemode \
+ -Dwith-sd-bus-provider=no-daemon \
+ -Dwith-systemd-user-unit-dir=/usr/lib/systemd/user \
+ -Dwith-util=false
+ meson compile -C build
+}
+
+check() {
+ meson test -C build
+}
+
+package() {
+ DESTDIR="${pkgdir}" meson install -C build
+ rm -rf "${pkgdir}"/{etc,usr/include}
+ install -dm 755 "${pkgdir}"/usr/share/licenses
+ ln -s gamemode "${pkgdir}"/usr/share/licenses/lib32-gamemode
+}
+
+# vim: set ts=4 sw=4 tw=0 et :
More information about the arch-commits
mailing list