[arch-commits] Commit in libretro-play/repos (2 files)

[Felix Yan]

    Date: Sunday, March 6, 2022 @ 16:10:45
  Author: felixonmars
Revision: 1142748

archrelease: copy trunk to community-staging-x86_64

Added:
  libretro-play/repos/community-staging-x86_64/
  libretro-play/repos/community-staging-x86_64/PKGBUILD
    (from rev 1142747, libretro-play/trunk/PKGBUILD)

----------+
 PKGBUILD |   88 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 88 insertions(+)

Copied: libretro-play/repos/community-staging-x86_64/PKGBUILD (from rev 1142747, libretro-play/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-03-06 16:10:45 UTC (rev 1142748)
@@ -0,0 +1,88 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+
+pkgname=libretro-play
+pkgver=6906
+pkgrel=2
+pkgdesc='Sony PlayStation 2 core'
+arch=(x86_64)
+url=https://github.com/jpd002/Play-
+license=(MIT)
+groups=(libretro)
+depends=(
+  bzip2
+  glew
+  glibc
+  icu
+  libgl
+  libretro-core-info
+  zlib
+)
+makedepends=(
+  cmake
+  git
+  libglvnd
+)
+_commit=e7dcd545c4b71894777e585933ecba036afe63d8
+source=(
+  libretro-play::git+https://github.com/jpd002/Play-.git#commit=${_commit}
+  play-CodeGen::git+https://github.com/jpd002/Play--CodeGen.git
+  play-Dependencies::git+https://github.com/jpd002/Play-Dependencies.git
+  play-Framework::git+https://github.com/jpd002/Play--Framework.git
+  play-libchdr::git+https://github.com/jpd002/libchdr.git
+  play-Nuanceur::git+https://github.com/jpd002/Nuanceur.git
+  git+https://github.com/SDWebImage/SDWebImage.git
+  git+https://github.com/gulrak/filesystem.git
+)
+b2sums=(
+  SKIP
+  SKIP
+  SKIP
+  SKIP
+  SKIP
+  SKIP
+  SKIP
+  SKIP
+)
+
+pkgver() {
+  cd libretro-play
+  git rev-list --count HEAD
+}
+
+prepare() {
+  cd libretro-play
+
+  for submodule in deps/{CodeGen,Dependencies,Framework,Nuanceur,libchdr}; do
+    git submodule init ${submodule}
+    git config submodule.${submodule}.url ../play-${submodule#*/}
+    git submodule update ${submodule}
+  done
+
+  cd deps/Dependencies
+
+  git submodule init SDWebImage
+  git config submodule.SDWebImage.url ../../../SDWebImage
+  git submodule update SDWebImage
+
+  git submodule init ghc_filesystem
+  git config submodule.ghc_filesystem.url ../../../filesystem
+  git submodule update ghc_filesystem
+}
+
+build() {
+  cmake -S libretro-play -B build \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DBUILD_LIBRETRO_CORE=ON \
+    -DBUILD_PLAY=OFF \
+    -DBUILD_TESTS=OFF \
+    -DENABLE_AMAZON_S3=OFF \
+    -Wno-dev
+  make -C build
+}
+
+package() {
+  install -Dm 644 build/Source/ui_libretro/play_libretro.so -t "${pkgdir}"/usr/lib/libretro/
+  install -Dm 644 libretro-play/License.txt -t "${pkgdir}"/usr/share/licenses/libretro-play/
+}
+
+# vim: ts=2 sw=2 et: