[arch-commits] Commit in switchboard/repos (2 files)

[Evangelos Foutras]

    Date: Sunday, March 6, 2022 @ 16:44:40
  Author: foutrelis
Revision: 1142781

archrelease: copy trunk to community-staging-x86_64

Added:
  switchboard/repos/community-staging-x86_64/
  switchboard/repos/community-staging-x86_64/PKGBUILD
    (from rev 1142780, switchboard/trunk/PKGBUILD)

----------+
 PKGBUILD |   67 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 67 insertions(+)

Copied: switchboard/repos/community-staging-x86_64/PKGBUILD (from rev 1142780, switchboard/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-03-06 16:44:40 UTC (rev 1142781)
@@ -0,0 +1,67 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: Ner0 <darkelfdarkelf666 at yahoo.co.uk>
+# Contributor: dserban <dserban01 at yahoo.com>
+
+pkgname=switchboard
+pkgver=6.0.0
+pkgrel=2
+pkgdesc='The Pantheon Control Center'
+arch=(x86_64)
+url=https://github.com/elementary/switchboard
+license=(GPL3)
+groups=(pantheon)
+depends=(
+  clutter-gtk
+  gdk-pixbuf2
+  glib2
+  gtk3
+  libgee
+  libgranite.so
+  libhandy-1.so
+  wayland
+)
+makedepends=(
+  git
+  meson
+  intltool
+  vala
+)
+optdepends=(
+  'switchboard-plug-about: About plug'
+  'switchboard-plug-applications: Applications plug'
+  'switchboard-plug-datetime: Date & Time plug'
+  'switchboard-plug-desktop: Desktop plug'
+  'switchboard-plug-display: Display plug'
+  'switchboard-plug-elementary-tweaks: Elementary Tweaks plug'
+  'switchboard-plug-keyboard: Keyboard plug'
+  'switchboard-plug-locale: Locale plug'
+  'switchboard-plug-network: Network plug'
+  'switchboard-plug-notifications: Notifications plug'
+  'switchboard-plug-power: Power plug'
+  'switchboard-plug-security-privacy: Security & Privacy plug'
+)
+provides=(libswitchboard-2.0.so)
+_tag=f4a24fdcff6d0bb96ead0b967d681d35e999f84c
+source=(git+https://github.com/elementary/switchboard.git#tag=${_tag})
+b2sums=(SKIP)
+
+prepare() {
+  cd switchboard
+  git cherry-pick -n ecf2a6c42122946cc84150f6927ef69c1f67c909
+}
+
+pkgver() {
+  cd switchboard
+  git describe --tags
+}
+
+build() {
+  arch-meson switchboard build
+  ninja -C build
+}
+
+package() {
+  DESTDIR="${pkgdir}" meson install -C build
+}
+
+# vim: ts=2 sw=2 et: