[arch-commits] Commit in lib32-libtheora/repos (2 files)

[Felix Yan]

    Date: Sunday, March 6, 2022 @ 17:00:29
  Author: felixonmars
Revision: 1142795

archrelease: copy trunk to multilib-staging-x86_64

Added:
  lib32-libtheora/repos/multilib-staging-x86_64/
  lib32-libtheora/repos/multilib-staging-x86_64/PKGBUILD
    (from rev 1142794, lib32-libtheora/trunk/PKGBUILD)

----------+
 PKGBUILD |   57 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)

Copied: lib32-libtheora/repos/multilib-staging-x86_64/PKGBUILD (from rev 1142794, lib32-libtheora/trunk/PKGBUILD)
===================================================================
--- multilib-staging-x86_64/PKGBUILD	                        (rev 0)
+++ multilib-staging-x86_64/PKGBUILD	2022-03-06 17:00:29 UTC (rev 1142795)
@@ -0,0 +1,57 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: Nicky726 <nicky726 at gmail.com>
+# Contributor: Tom Killian <tom at archlinux.org>
+# Contributor: Rémy Oudompheng <remyoudompheng at gmail.com>
+
+pkgname=lib32-libtheora
+pkgver=1.1.1
+pkgrel=13
+pkgdesc='An open video codec developed by the Xiph.org'
+arch=(x86_64)
+url=https://www.xiph.org
+license=(BSD)
+depends=(
+  lib32-libogg
+  libtheora
+)
+makedepends=(
+  git
+  lib32-libvorbis
+)
+source=(https://downloads.xiph.org/releases/theora/libtheora-${pkgver}.tar.bz2)
+sha256sums=('b6ae1ee2fa3d42ac489287d3ec34c5885730b1296f0801ae577a35193d3affbc')
+
+prepare() {
+  cd libtheora-$pkgver
+
+  sed 's/AC_DEFINE(\[OC_X86_64_ASM\]/#AC_DEFINE(\[OC_X86_64_ASM\]/
+       s/AM_CONFIG_HEADER/AC_CONFIG_HEADERS/' -i configure.ac
+}
+
+build() {
+  cd libtheora-$pkgver
+
+  export CC='gcc -m32'
+  export CXX='g++ -m32'
+  export PKG_CONFIG_PATH='/usr/lib32/pkgconfig'
+
+  ./autogen.sh \
+    --prefix='/usr' \
+    --libdir='/usr/lib32' \
+    --with-pic \
+    --disable-examples \
+    --disable-static
+  make
+}
+
+package() {
+  cd libtheora-$pkgver
+
+  make DESTDIR="${pkgdir}" install
+  rm -rf "${pkgdir}"/usr/{include,share}
+
+  install -dm 755 "${pkgdir}"/usr/share/licenses
+  ln -s libtheora "${pkgdir}"/usr/share/licenses/lib32-libtheora
+}
+
+# vim: ts=2 sw=2 et: