[arch-commits] Commit in haskell-clash-prelude/repos (2 files)

[Felix Yan]

    Date: Friday, March 11, 2022 @ 01:04:49
  Author: felixonmars
Revision: 1147058

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-clash-prelude/repos/community-staging-x86_64/
  haskell-clash-prelude/repos/community-staging-x86_64/PKGBUILD
    (from rev 1147057, haskell-clash-prelude/trunk/PKGBUILD)

----------+
 PKGBUILD |   57 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)

Copied: haskell-clash-prelude/repos/community-staging-x86_64/PKGBUILD (from rev 1147057, haskell-clash-prelude/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-03-11 01:04:49 UTC (rev 1147058)
@@ -0,0 +1,57 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=clash-prelude
+pkgname=haskell-clash-prelude
+pkgver=1.4.7
+pkgrel=6
+pkgdesc="Clash: a functional hardware description language - Prelude library"
+url="https://github.com/clash-lang/clash-prelude"
+license=('BSD')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-arrows' 'haskell-bifunctors' 'haskell-constraints'
+         'haskell-data-binary-ieee754' 'haskell-data-default-class' 'haskell-extra'
+         'haskell-ghc-typelits-extra' 'haskell-ghc-typelits-knownnat'
+         'haskell-ghc-typelits-natnormalise' 'haskell-half' 'haskell-hashable' 'haskell-interpolate'
+         'haskell-lens' 'haskell-quickcheck' 'haskell-recursion-schemes' 'haskell-reflection'
+         'haskell-singletons' 'haskell-th-abstraction' 'haskell-th-lift' 'haskell-text-show'
+         'haskell-th-orphans' 'haskell-type-errors' 'haskell-uniplate' 'haskell-vector')
+makedepends=('ghc' 'uusi' 'haskell-cabal-doctest' 'haskell-doctest' 'haskell-hedgehog'
+             'haskell-hint' 'haskell-quickcheck-classes-base' 'haskell-tasty'
+             'haskell-tasty-hedgehog' 'haskell-tasty-hunit' 'haskell-tasty-quickcheck'
+             'haskell-tasty-th')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('8e8d35aa7795fcb38886b11b5ffd62185c5f731beb9c4ca9aebbc9dd3c77aa7558a1fb09655668974ef69bbc8ffa06abddf9558feefc065dbd149caa583a6151')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    uusi -u doctest $_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    # TODO
+    runhaskell Setup test --show-details=direct || warning "Tests failed"
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}