[arch-commits] Commit in haskell-double-conversion/repos (2 files)

[Felix Yan]

    Date: Friday, March 11, 2022 @ 03:23:38
  Author: felixonmars
Revision: 1147356

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-double-conversion/repos/community-staging-x86_64/
  haskell-double-conversion/repos/community-staging-x86_64/PKGBUILD
    (from rev 1147355, haskell-double-conversion/trunk/PKGBUILD)

----------+
 PKGBUILD |   51 +++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)

Copied: haskell-double-conversion/repos/community-staging-x86_64/PKGBUILD (from rev 1147355, haskell-double-conversion/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-03-11 03:23:38 UTC (rev 1147356)
@@ -0,0 +1,51 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=double-conversion
+pkgname=haskell-double-conversion
+pkgver=2.0.2.0
+pkgrel=153
+pkgdesc="Fast conversion between double precision floating point and text"
+url="https://github.com/bos/double-conversion"
+license=('MIT')
+arch=('x86_64')
+depends=('ghc-libs' 'double-conversion')
+makedepends=('ghc' 'haskell-hunit' 'haskell-test-framework' 'haskell-test-framework-hunit'
+             'haskell-test-framework-quickcheck2')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz
+        system-double-conversion.patch::https://github.com/bos/double-conversion/pull/25.patch)
+sha512sums=('1713c4e8a28de2ee85e1f312dc12d30a9c6d7a139d89f04ea88048578ce65c8bdf62ded90b92bce011955b95867ca95a623a5109758276a29ba7b6843fbe37eb'
+            'fca512e2787ab4faf587db28b1212c99681926dc32b95a739df8fb33925439385862b55aaf68dfe737b1709335ec44f8e959e40b74012d56f3506e36b31ddabe')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    patch -p1 -i ../system-double-conversion.patch
+}
+
+build() {
+    cd $_hkgname-$pkgver    
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm \
+            -f-embedded_double_conversion
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test --show-details=direct
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}