[arch-commits] Commit in haskell-commonmark-extensions/repos (2 files)

Felix Yan felixonmars at gemini.archlinux.org
Fri Mar 11 08:13:15 UTC 2022


    Date: Friday, March 11, 2022 @ 08:13:15
  Author: felixonmars
Revision: 1147982

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-commonmark-extensions/repos/community-staging-x86_64/
  haskell-commonmark-extensions/repos/community-staging-x86_64/PKGBUILD
    (from rev 1147981, haskell-commonmark-extensions/trunk/PKGBUILD)

----------+
 PKGBUILD |   48 ++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

Copied: haskell-commonmark-extensions/repos/community-staging-x86_64/PKGBUILD (from rev 1147981, haskell-commonmark-extensions/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-03-11 08:13:15 UTC (rev 1147982)
@@ -0,0 +1,48 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Maintainer: Caleb Maclennan <caleb at alerque.com>
+
+_hkgname=commonmark-extensions
+pkgname=haskell-commonmark-extensions
+pkgver=0.2.2.1
+pkgrel=11
+pkgdesc="Pure Haskell commonmark parser"
+url="https://github.com/jgm/commonmark-hs"
+license=('BSD')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-commonmark' 'haskell-emojis' 'haskell-network-uri')
+makedepends=('ghc' 'uusi' 'haskell-tasty' 'haskell-tasty-hunit')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('ef371e8fa92d489f160d6f86d62be1da3b0c27e184a0ce5370c9c599c3cfab358646efcb7795d741ca1c6771a616ed08c8e88737c8a595a8ff74fb8322d3a4d1')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    gen-setup
+}
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test --show-details=direct
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}



More information about the arch-commits mailing list