[arch-commits] Commit in haskell-zip-archive/repos (2 files)

[Felix Yan]

    Date: Monday, March 14, 2022 @ 00:57:59
  Author: felixonmars
Revision: 1152019

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-zip-archive/repos/community-staging-x86_64/
  haskell-zip-archive/repos/community-staging-x86_64/PKGBUILD
    (from rev 1152018, haskell-zip-archive/trunk/PKGBUILD)

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Copied: haskell-zip-archive/repos/community-staging-x86_64/PKGBUILD (from rev 1152018, haskell-zip-archive/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-03-14 00:57:59 UTC (rev 1152019)
@@ -0,0 +1,45 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=zip-archive
+pkgname=haskell-zip-archive
+pkgver=0.4.2
+pkgrel=2
+pkgdesc="Library for creating and modifying zip archives."
+url="https://github.com/jgm/zip-archive"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-digest' 'haskell-old-time' 'haskell-temporary'
+         'haskell-zlib')
+makedepends=('ghc' 'haskell-hunit' 'unzip')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/jgm/zip-archive/archive/$pkgver.tar.gz")
+sha512sums=('171da0c12c14e3ad3e1f30a7ac7b0c30f2b163e6239e58c69ce15f404dcf79e3025c0b0bd2368f0000439bac5d921d71fa35686000426b1084eedbe31c341328')
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm \
+            -f-executable -fsplitbase
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test --show-details=direct
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}