[arch-commits] Commit in innernet/repos (2 files)

[Caleb Maclennan]

    Date: Wednesday, March 16, 2022 @ 11:11:13
  Author: alerque
Revision: 1155369

archrelease: copy trunk to community-testing-x86_64

Added:
  innernet/repos/community-testing-x86_64/
  innernet/repos/community-testing-x86_64/PKGBUILD
    (from rev 1155368, innernet/trunk/PKGBUILD)

----------+
 PKGBUILD |   54 ++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)

Copied: innernet/repos/community-testing-x86_64/PKGBUILD (from rev 1155368, innernet/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2022-03-16 11:11:13 UTC (rev 1155369)
@@ -0,0 +1,54 @@
+# Maintainer: Orhun Parmaksız <orhun at archlinux.org>
+# Maintainer: Caleb Maclennan <caleb at alerque.com>
+# Contributor: Jake McGinty <jake at tonari.no>
+
+pkgname=innernet
+pkgver=1.5.4
+pkgrel=1
+pkgdesc="A private network system that uses WireGuard under the hood"
+arch=('x86_64')
+url="https://github.com/tonarino/innernet"
+license=('MIT')
+depends=('sqlite')
+makedepends=('rust' 'git' 'clang' 'llvm')
+source=("$url/archive/v$pkgver/$pkgname-$pkgver.tar.gz")
+sha256sums=('235fab9fbf67be8667ac0ec89f7fc45771b28d85be791ac3d9ae9a4d21e15673')
+
+prepare() {
+  cd "$pkgname-$pkgver"
+  cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
+}
+
+build() {
+  cd "$pkgname-$pkgver"
+  cargo build --release --frozen
+}
+
+check() {
+  cd "$pkgname-$pkgver"
+  cargo test --frozen
+}
+
+package() {
+  cd "$pkgname-$pkgver"
+
+  install -Dm 755 "target/release/$pkgname" "$pkgdir/usr/bin/$pkgname"
+  install -Dm 755 "target/release/$pkgname-server" "$pkgdir/usr/bin/$pkgname-server"
+
+  install -Dm 644 "client/$pkgname at .service" "$pkgdir/usr/lib/systemd/system/$pkgname at .service"
+  install -Dm 644 "client/$pkgname.target" "$pkgdir/usr/lib/systemd/system/$pkgname.target"
+
+  install -Dm 644 "server/$pkgname-server at .service" "$pkgdir/usr/lib/systemd/system/$pkgname-server at .service"
+
+  for binary in "$pkgname" "$pkgname-server"; do
+    install -Dm 644 "doc/$binary.completions.bash" "$pkgdir/usr/share/bash-completion/completions/$binary"
+    install -Dm 644 "doc/$binary.completions.fish" "$pkgdir/usr/share/fish/vendor_completions.d/$binary.fish"
+    install -Dm 644 "doc/$binary.completions.zsh" "$pkgdir/usr/share/zsh/site-functions/_$binary"
+    install -Dm 644 "doc/$binary.8.gz" "$pkgdir/usr/share/man/man8/$binary.8.gz"
+  done
+
+  install -Dm 644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+  install -Dm 644 README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
+}
+
+# vim:set ts=2 sw=2 et: