[arch-commits] Commit in vala/repos (testing-x86_64 testing-x86_64/PKGBUILD)

[Jan Steffens]

    Date: Thursday, March 17, 2022 @ 20:43:28
  Author: heftig
Revision: 439879

archrelease: copy trunk to testing-x86_64

Added:
  vala/repos/testing-x86_64/
  vala/repos/testing-x86_64/PKGBUILD
    (from rev 439878, vala/trunk/PKGBUILD)

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Copied: vala/repos/testing-x86_64/PKGBUILD (from rev 439878, vala/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2022-03-17 20:43:28 UTC (rev 439879)
@@ -0,0 +1,50 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Ionut Biru <ibiru at archlinux.org>
+# Contributor: Timm Preetz <timm at preetz.us>
+
+pkgname=vala
+pkgver=0.56.0
+pkgrel=1
+pkgdesc='Compiler for the GObject type system'
+url='https://wiki.gnome.org/Projects/Vala'
+arch=(x86_64)
+license=(LGPL)
+depends=(glib2 gtk-doc graphviz ttf-font pkg-config gcc)
+makedepends=(libxslt vala git help2man autoconf-archive)
+checkdepends=(dbus libx11 gobject-introspection)
+provides=(valadoc libvala-${pkgver%.*}.so libvaladoc-${pkgver%.*}.so)
+conflicts=(valadoc)
+replaces=(valadoc)
+_commit=e6f675dc4916334e46b0e1af19d072bec48f39ca  # tags/0.56.0^0
+source=("git+https://gitlab.gnome.org/GNOME/vala.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd vala
+  git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
+}
+
+prepare() {
+  cd vala
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd vala
+  ./configure --prefix=/usr
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+  make
+}
+
+check() {
+  cd vala
+  make check
+}
+
+package() {
+  cd vala
+  make DESTDIR="$pkgdir" install
+}
+
+# vim:set sw=2 et: