[arch-commits] Commit in spirv-llvm-translator/repos (2 files)

[Bruno Pagani]

    Date: Thursday, March 17, 2022 @ 20:59:36
  Author: archange
Revision: 1157070

archrelease: copy trunk to community-testing-x86_64

Added:
  spirv-llvm-translator/repos/community-testing-x86_64/
  spirv-llvm-translator/repos/community-testing-x86_64/PKGBUILD
    (from rev 1157069, spirv-llvm-translator/trunk/PKGBUILD)

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Copied: spirv-llvm-translator/repos/community-testing-x86_64/PKGBUILD (from rev 1157069, spirv-llvm-translator/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2022-03-17 20:59:36 UTC (rev 1157070)
@@ -0,0 +1,47 @@
+# Maintainer: Daniel Bermond <dbermond at archlinux.org>
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+
+_srcname=SPIRV-LLVM-Translator
+pkgname=${_srcname,,}
+pkgver=13.0.0.r23+gc9f1e369
+pkgrel=1
+pkgdesc="Tool and a library for bi-directional translation between SPIR-V and LLVM IR"
+arch=(x86_64)
+url="https://github.com/KhronosGroup/SPIRV-LLVM-Translator"
+license=(custom)
+depends=(llvm-libs)
+makedepends=(git cmake llvm spirv-headers spirv-tools)
+checkdepends=(python python-setuptools clang)
+_commit=c9f1e36957255656b52bc9013e24e3201990eeee # Adapted from IGC release notes
+source=(git+${url}.git#commit=$_commit)
+sha256sums=(SKIP)
+
+pkgver() {
+    cd ${_srcname}
+    git describe --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./;s/-/+/'
+}
+
+build() {
+    cmake -B build -S ${_srcname} \
+        -DBUILD_SHARED_LIBS=ON \
+        -DCMAKE_BUILD_TYPE=Release \
+        -DCMAKE_INSTALL_PREFIX=/usr \
+        -DCMAKE_POSITION_INDEPENDENT_CODE=ON \
+        -DCMAKE_SKIP_RPATH=ON \
+        -DLLVM_INCLUDE_TESTS=ON \
+        -DLLVM_EXTERNAL_LIT=/usr/bin/lit \
+        -DLLVM_EXTERNAL_SPIRV_HEADERS_SOURCE_DIR=/usr/include/spirv/ \
+        -Wno-dev
+    make -C build
+}
+
+check() {
+    # https://github.com/KhronosGroup/SPIRV-LLVM-Translator/issues/1433
+    LD_LIBRARY_PATH="${srcdir}/build/lib/SPIRV" make -C build test || echo "Tests failed"
+}
+
+package() {
+    make -C build DESTDIR="${pkgdir}" install
+    install -Dm755 build/tools/llvm-spirv/llvm-spirv -t "${pkgdir}"/usr/bin
+    install -Dm644 ${_srcname}/LICENSE.TXT -t "${pkgdir}"/usr/share/licenses/${pkgname}/
+}