[arch-commits] Commit in haskell-libbf/repos (2 files)

[Felix Yan]

    Date: Friday, March 18, 2022 @ 01:58:22
  Author: felixonmars
Revision: 1157918

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-libbf/repos/community-staging-x86_64/
  haskell-libbf/repos/community-staging-x86_64/PKGBUILD
    (from rev 1157917, haskell-libbf/trunk/PKGBUILD)

----------+
 PKGBUILD |   43 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)

Copied: haskell-libbf/repos/community-staging-x86_64/PKGBUILD (from rev 1157917, haskell-libbf/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-03-18 01:58:22 UTC (rev 1157918)
@@ -0,0 +1,43 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=libBF
+pkgname=haskell-libbf
+pkgver=0.6.3
+pkgrel=15
+pkgdesc="A binding to the libBF library"
+url="https://github.com/GaloisInc/libBF-hs"
+license=('MIT')
+arch=('x86_64')
+depends=('ghc-libs' 'libbf' 'haskell-hashable')
+makedepends=('ghc')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('bb63094e538320e2a64a5b298686c0e93d02061569a219a5becfd9ae53874ddec3a3c464dbcfdc6feff8e32abaa456308602dd7e657c33cc643fcee766e9251a')
+
+build() {
+    cd $_hkgname-$pkgver    
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm \
+        -fsystem-libbf
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test --show-details=direct
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}