[arch-commits] Commit in jami-daemon/repos (2 files)

[Bruno Pagani]

    Date: Friday, March 18, 2022 @ 11:43:43
  Author: archange
Revision: 1158420

archrelease: copy trunk to community-staging-x86_64

Added:
  jami-daemon/repos/community-staging-x86_64/
  jami-daemon/repos/community-staging-x86_64/PKGBUILD
    (from rev 1158419, jami-daemon/trunk/PKGBUILD)

----------+
 PKGBUILD |   60 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 60 insertions(+)

Copied: jami-daemon/repos/community-staging-x86_64/PKGBUILD (from rev 1158419, jami-daemon/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-03-18 11:43:43 UTC (rev 1158420)
@@ -0,0 +1,60 @@
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+# Contributor: Baptiste Jonglez <baptiste--aur at jonglez dot org>
+
+pkgname=jami-daemon
+pkgver=20220317
+pkgrel=1
+pkgdesc="Free and universal communication platform which preserves the users’ privacy and freedoms (daemon component)"
+arch=(x86_64)
+url="https://jami.net"
+license=(GPL3)
+groups=(jami)
+depends=(glibc opendht gnutls nettle libgit2 libsecp256k1 ffmpeg speexdsp
+         fmt yaml-cpp jsoncpp zlib dbus-c++ alsa-lib libpulse jack
+         libupnp libnatpmp openssl webrtc-audio-processing systemd-libs
+         libarchive)
+# portaudio needs a not-yet-upstream patch https://git.jami.net/savoirfairelinux/jami-daemon/-/issues/650
+makedepends=(git cmake perl asio msgpack-c msgpack-cxx restinio systemd meson)
+checkdepends=(cppunit)
+_commit=f6f8a83754351d640b90026d1c6b59b2b6ed1393
+_pjprojectver=e1f389d0b905011e0cb62cbdf7a8b37fc1bcde1a
+source=(git+https://git.jami.net/savoirfairelinux/${pkgname}.git#commit=${_commit}
+        https://github.com/savoirfairelinux/pjproject/archive/${_pjprojectver}/pjproject-${_pjprojectver}.tar.gz)
+noextract=(pjproject-${_pjprojectver}.tar.gz)
+sha512sums=(SKIP a1ed0519ddf8dc91f47042497530cbcb1c8736506d0c2b677751a3368c0a202952ff563946664705dbf5806bed8ade784885db62f8278a204f516a4e60917b1e)
+
+pkgver() {
+  cd ${pkgname}
+  TZ=UTC git show -s --pretty=%cd --date=format-local:%Y%m%d HEAD
+}
+
+prepare() {
+  cd ${pkgname}
+  cp ../pjproject-${_pjprojectver}.tar.gz contrib/tarballs
+  mkdir contrib/native
+}
+
+build() {
+  cd ${pkgname}/contrib/native
+  export CXXFLAGS+=' -fpermissive'
+  ../bootstrap \
+      --disable-downloads \
+      --disable-all \
+      --enable-pjproject
+  make DEPS_pjproject=
+
+  cd "${srcdir}"
+  arch-meson ${pkgname} build -D interfaces=library,dbus -D opensl=disabled -D portaudio=disabled \
+                              $( ((CHECKFUNC)) && echo -D tests=true) \
+                              -D pkg_config_path="${PWD}/${pkgname}/contrib/$(cc -dumpmachine)/lib/pkgconfig"
+  meson compile -C build
+}
+
+#check() {
+# https://git.jami.net/savoirfairelinux/jami-daemon/-/issues/649
+#  meson test -C build --print-errorlogs
+#}
+
+package() {
+  meson install -C build --destdir "${pkgdir}"
+}