[arch-commits] Commit in gobject-introspection/repos (2 files)
Jan Steffens
heftig at gemini.archlinux.org
Fri Mar 18 13:16:54 UTC 2022
Date: Friday, March 18, 2022 @ 13:16:54
Author: heftig
Revision: 439923
archrelease: copy trunk to testing-x86_64
Added:
gobject-introspection/repos/testing-x86_64/
gobject-introspection/repos/testing-x86_64/PKGBUILD
(from rev 439922, gobject-introspection/trunk/PKGBUILD)
----------+
PKGBUILD | 73 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 73 insertions(+)
Copied: gobject-introspection/repos/testing-x86_64/PKGBUILD (from rev 439922, gobject-introspection/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD (rev 0)
+++ testing-x86_64/PKGBUILD 2022-03-18 13:16:54 UTC (rev 439923)
@@ -0,0 +1,73 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+
+pkgbase=gobject-introspection
+pkgname=(gobject-introspection gobject-introspection-runtime)
+pkgver=1.72.0
+pkgrel=1
+pkgdesc="Introspection system for GObject-based libraries"
+url="https://wiki.gnome.org/Projects/GObjectIntrospection"
+arch=(x86_64)
+license=(LGPL GPL)
+_glibver=2.72.0
+depends=(python-mako python-markdown)
+makedepends=(cairo git gtk-doc python-sphinx meson "glib2=$_glibver")
+options=(debug)
+_commit=c1ce7d179cfce327162bd206cdf2808bd9bd0cc7 # tags/1.72.0^0
+source=("git+https://gitlab.gnome.org/GNOME/gobject-introspection.git#commit=$_commit"
+ "git+https://gitlab.gnome.org/GNOME/glib.git?signed#tag=$_glibver")
+sha512sums=('SKIP'
+ 'SKIP')
+validpgpkeys=('923B7025EE03C1C59F42684CF0942E894B2EAFA0') # Philip Withnall <philip at tecnocode.co.uk>
+
+pkgver() {
+ cd $pkgbase
+ git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
+}
+
+prepare() {
+ cd $pkgbase
+}
+
+build() {
+ arch-meson $pkgbase build \
+ -D gtk_doc=true \
+ -D glib_src_dir="$srcdir/glib"
+ meson compile -C build
+}
+
+check() {
+ meson test -C build
+}
+
+_pick() {
+ local p="$1" f d; shift
+ for f; do
+ d="$srcdir/$p/${f#$pkgdir/}"
+ mkdir -p "$(dirname "$d")"
+ mv "$f" "$d"
+ rmdir -p --ignore-fail-on-non-empty "$(dirname "$f")"
+ done
+}
+
+package_gobject-introspection() {
+ depends+=("gobject-introspection-runtime=$pkgver-$pkgrel")
+
+ meson install -C build --destdir "$pkgdir"
+
+ cd "$pkgdir"
+
+ python -m compileall -d /usr/lib/$pkgbase usr/lib/$pkgbase
+ python -O -m compileall -d /usr/lib/$pkgbase usr/lib/$pkgbase
+
+ _pick runtime usr/lib/lib*
+ _pick runtime usr/lib/girepository-*
+}
+
+package_gobject-introspection-runtime() {
+ pkgdesc+=" (runtime library)"
+ depends=(glib2)
+ provides+=(libgirepository-1.0.so)
+
+ mv runtime/* "$pkgdir"
+}
More information about the arch-commits
mailing list