[arch-commits] Commit in haskell-kan-extensions/repos (2 files)

[Felix Yan]

    Date: Friday, March 18, 2022 @ 16:11:26
  Author: felixonmars
Revision: 1158558

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-kan-extensions/repos/community-staging-x86_64/
  haskell-kan-extensions/repos/community-staging-x86_64/PKGBUILD
    (from rev 1158557, haskell-kan-extensions/trunk/PKGBUILD)

----------+
 PKGBUILD |   40 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 40 insertions(+)

Copied: haskell-kan-extensions/repos/community-staging-x86_64/PKGBUILD (from rev 1158557, haskell-kan-extensions/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-03-18 16:11:26 UTC (rev 1158558)
@@ -0,0 +1,40 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=kan-extensions
+pkgname=haskell-kan-extensions
+pkgver=5.2.3
+pkgrel=49
+pkgdesc="Kan extensions, Kan lifts, the Yoneda lemma, and (co)density (co)monads"
+url="https://github.com/ekmett/kan-extensions/"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-adjunctions' 'haskell-comonad' 'haskell-contravariant'
+         'haskell-distributive' 'haskell-free' 'haskell-invariant' 'haskell-profunctors'
+         'haskell-semigroupoids' 'haskell-tagged' 'haskell-transformers-compat')
+makedepends=('ghc')
+source=("https://hackage.haskell.org/packages/archive/$_hkgname/$pkgver/$_hkgname-$pkgver.tar.gz")
+sha512sums=('a3bb00dec4652042754c00dd4b2ef02b3ed4d74f4f9b8edea36e77c8516ef5b2f9853af20ab63e8f03fc91745ceb286a71ee35b0c82cbc7b0452bbb5e9012f80')
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}