[arch-commits] Commit in python-blosc/trunk (PKGBUILD)

[Bruno Pagani]

    Date: Friday, March 18, 2022 @ 21:32:32
  Author: archange
Revision: 1159179

FS#74129 Fix bytecode missing and -O3 compilation

Also revamp PKGBUILD and enable tests.

Modified:
  python-blosc/trunk/PKGBUILD

----------+
 PKGBUILD |   40 ++++++++++++++++++++--------------------
 1 file changed, 20 insertions(+), 20 deletions(-)

Modified: PKGBUILD
===================================================================
--- PKGBUILD	2022-03-18 21:32:14 UTC (rev 1159178)
+++ PKGBUILD	2022-03-18 21:32:32 UTC (rev 1159179)
@@ -1,35 +1,35 @@
 # Maintainer: Andrzej Giniewicz <gginiu at gmail.com>
+# Maintainer: Bruno Pagani <archange at archlinux.org>
 
 pkgname=python-blosc
 pkgver=1.10.6
-pkgrel=3
-pkgdesc="A Python wrapper for the extremely fast Blosc compression library"
-arch=('x86_64')
+pkgrel=4
+pkgdesc="Python wrapper for the extremely fast Blosc compression library"
+arch=(x86_64)
 url="http://python-blosc.blosc.org/"
-license=('BSD')
-depends=('python' 'blosc')
+license=(BSD)
+depends=(python blosc)
 optdepends=('python-numpy: for tests and benchmarks')
-makedepends=('python-scikit-build' 'ninja')
-source=("${pkgname}-${pkgver}.tar.gz::https://github.com/Blosc/python-blosc/archive/v${pkgver}.tar.gz")
+makedepends=(python-scikit-build ninja)
+checkdepends=(python-numpy python-psutil)
+source=(https://github.com/Blosc/python-blosc/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz)
 sha512sums=('e283b132ebb91e7ce362ec65a1d6760e3793046371ea545a9e842372084182bcc194c3a0e1cb20914de58554063995a238ea0a129214731689e8cd5f4203d3ed')
 b2sums=('44f444fa5050a6198e83649973fc82d6804eec50bf79c332ed6a974e417f2a58baf09480a9bb5c5b7abcef2a961cd7bc61f962c12db625b1a7c48799ace0b39a')
 
-prepare() {
-  sed -e '/c-blosc/d' -e 's|blosc_static|blosc|' \
-    -i $pkgname-$pkgver/blosc/CMakeLists.txt # Use system blosc
+build() {
+  cd ${pkgname}-${pkgver}
+  export INCLUDE_SNAPPY=1 # Disabled by default for compatibility with non-C++ systems
+  python setup.py build --build-type none -DUSE_SYSTEM_BLOSC=ON -DCMAKE_C_FLAGS_INIT=-DNDEBUG
 }
 
-build() {
-  cd "$pkgname-$pkgver"
-  BLOSC_DIR=/usr
-  export BLOSC_DIR
-  python setup.py build_clib
-  python setup.py build_ext --inplace
-  python setup.py build
+check() {
+  local python_version=$(python -c 'import sys; print(".".join(map(str, sys.version_info[:2])))')
+  cd ${pkgname}-${pkgver}/_skbuild/linux-${CARCH}-${python_version}/setuptools/lib
+  PYTHONPATH=${PWD} python blosc/test.py -v
 }
 
 package() {
-  cd "$pkgname-$pkgver"
-  python setup.py install --skip-build --root="$pkgdir" --optimize=1
-  install -Dm644 LICENSE.txt "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+  cd ${pkgname}-${pkgver}
+  python setup.py --skip-cmake install --skip-build --root="${pkgdir}" --optimize=1
+  install -Dm644 LICENSE.txt -t "${pkgdir}"/usr/share/licenses/$pkgname/
 }