[arch-commits] Commit in haskell-lucid/repos (2 files)

[Felix Yan]

    Date: Sunday, March 20, 2022 @ 18:01:36
  Author: felixonmars
Revision: 1164617

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-lucid/repos/community-staging-x86_64/
  haskell-lucid/repos/community-staging-x86_64/PKGBUILD
    (from rev 1164616, haskell-lucid/trunk/PKGBUILD)

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Copied: haskell-lucid/repos/community-staging-x86_64/PKGBUILD (from rev 1164616, haskell-lucid/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-03-20 18:01:36 UTC (rev 1164617)
@@ -0,0 +1,44 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=lucid
+pkgname=haskell-lucid
+pkgver=2.11.0
+pkgrel=18
+pkgdesc="Clear to write, read and edit DSL for HTML"
+url="https://github.com/chrisdone/lucid"
+license=('BSD')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-blaze-builder' 'haskell-hashable' 'haskell-mmorph'
+         'haskell-unordered-containers')
+makedepends=('ghc' 'haskell-bifunctors' 'haskell-hspec' 'haskell-hunit')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('bdd3a1beaf787ad28858bd738b7ad6cb440e98ef8134abceb6def7a3f03a9df2a26d50b85532775d5250f9ad48a6b26b9fcc61fa7c4948c5c8639fe5dfea6e6f')
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    # Test result depending on version of hashable
+    runhaskell Setup test --show-details=direct || echo "Tests failed"
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}