[arch-commits] Commit in netcdf-openmpi/repos/community-x86_64 (PKGBUILD PKGBUILD)

[Bruno Pagani]

    Date: Sunday, March 20, 2022 @ 23:09:30
  Author: archange
Revision: 1166345

archrelease: copy trunk to community-x86_64

Added:
  netcdf-openmpi/repos/community-x86_64/PKGBUILD
    (from rev 1166344, netcdf-openmpi/trunk/PKGBUILD)
Deleted:
  netcdf-openmpi/repos/community-x86_64/PKGBUILD

----------+
 PKGBUILD |  113 +++++++++++++++++++++++++++++++------------------------------
 1 file changed, 59 insertions(+), 54 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2022-03-20 23:09:05 UTC (rev 1166344)
+++ PKGBUILD	2022-03-20 23:09:30 UTC (rev 1166345)
@@ -1,54 +0,0 @@
-# Maintainer: Ronald van Haren <ronald.archlinux.org>
-# Maintainer: Bruno Pagani <archange at archlinux.org>
-# Contributor: damir <damir at archlinux.org>
-
-_pkg=netcdf
-_mpi=openmpi
-pkgname=${_pkg}-${_mpi}
-pkgver=4.8.1
-pkgrel=1
-pkgdesc="network Common Data Form interface for array-oriented data access and corresponding library with parallel support (${_mpi} version)"
-arch=(x86_64)
-url="https://www.unidata.ucar.edu/software/netcdf/"
-license=(custom)
-depends=("hdf5-${_mpi}" "pnetcdf-${_mpi}" curl)
-makedepends=(cmake)
-optdepends=('netcdf-fortran: fortran bindings' 'netcdf-cxx: c++ bindings')
-checkdepends=(inetutils unzip)
-provides=("${_pkg}")
-conflicts=("${_pkg}")
-options=(!makeflags)
-source=(https://github.com/Unidata/netcdf-c/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz)
-sha256sums=('bc018cc30d5da402622bf76462480664c6668b55eb16ba205a0dfb8647161dd0')
-
-build() {
-  export CC=mpicc
-  cmake -B build -S ${_pkg}-c-${pkgver} \
-    -DCMAKE_INSTALL_PREFIX=/usr \
-    -DCMAKE_INSTALL_LIBDIR=lib \
-    -DCMAKE_BUILD_TYPE=Release \
-    -DENABLE_BYTERANGE=ON \
-    -DENABLE_CDF5=ON \
-    -DENABLE_PNETCDF=ON \
-    -DENABLE_DAP_LONG_TESTS=OFF \
-    -DENABLE_EXAMPLE_TESTS=ON \
-    -DENABLE_EXTRA_TESTS=ON \
-    -DENABLE_FILTER_TESTING=ON \
-    -DENABLE_LARGE_FILE_TESTS=ON \
-    -DENABLE_UNIT_TESTS=ON
-  make -C build
-}
-
-
-check() {
-  # This is required starting with OpenMPI 3.0 when trying to run more
-  # processes than the number of available cores
-  export OMPI_MCA_rmaps_base_oversubscribe=yes
-
-  make -C build test
-}
-
-package() {
-  make -C build DESTDIR="${pkgdir}" install
-  install -Dm644 ${_pkg}-c-${pkgver}/COPYRIGHT -t "${pkgdir}"/usr/share/licenses/${_pkg}/
-}

Copied: netcdf-openmpi/repos/community-x86_64/PKGBUILD (from rev 1166344, netcdf-openmpi/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2022-03-20 23:09:30 UTC (rev 1166345)
@@ -0,0 +1,59 @@
+# Maintainer: Ronald van Haren <ronald.archlinux.org>
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+# Contributor: damir <damir at archlinux.org>
+
+_pkg=netcdf
+_mpi=openmpi
+pkgname=${_pkg}-${_mpi}
+pkgver=4.8.1
+pkgrel=2
+pkgdesc="network Common Data Form interface for array-oriented data access and corresponding library with parallel support (${_mpi} version)"
+arch=(x86_64)
+url="https://www.unidata.ucar.edu/software/netcdf/"
+license=(custom)
+depends=("hdf5-${_mpi}" "pnetcdf-${_mpi}" curl)
+makedepends=(cmake)
+optdepends=('netcdf-fortran: fortran bindings' 'netcdf-cxx: c++ bindings')
+checkdepends=(inetutils unzip)
+provides=("${_pkg}")
+conflicts=("${_pkg}")
+options=(!makeflags)
+source=(https://github.com/Unidata/netcdf-c/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz)
+sha256sums=('bc018cc30d5da402622bf76462480664c6668b55eb16ba205a0dfb8647161dd0')
+
+prepare() {
+  # https://github.com/Unidata/netcdf-c/issues/2242
+  sed -i "/add_sh_test(ncdap tst_remote3)/d" ${_pkg}-c-${pkgver}/ncdap_test/CMakeLists.txt
+}
+
+build() {
+  export CC=mpicc
+  cmake -B build -S ${_pkg}-c-${pkgver} \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_INSTALL_LIBDIR=lib \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DENABLE_BYTERANGE=ON \
+    -DENABLE_CDF5=ON \
+    -DENABLE_PNETCDF=ON \
+    -DENABLE_DAP_LONG_TESTS=OFF \
+    -DENABLE_EXAMPLE_TESTS=ON \
+    -DENABLE_EXTRA_TESTS=ON \
+    -DENABLE_FILTER_TESTING=ON \
+    -DENABLE_LARGE_FILE_TESTS=ON \
+    -DENABLE_UNIT_TESTS=ON
+  make -C build
+}
+
+
+check() {
+  # This is required starting with OpenMPI 3.0 when trying to run more
+  # processes than the number of available cores
+  export OMPI_MCA_rmaps_base_oversubscribe=yes
+
+  make -C build test
+}
+
+package() {
+  make -C build DESTDIR="${pkgdir}" install
+  install -Dm644 ${_pkg}-c-${pkgver}/COPYRIGHT -t "${pkgdir}"/usr/share/licenses/${_pkg}/
+}